-
Notifications
You must be signed in to change notification settings - Fork 86
/
Copy pathitree_semanticsEquivScript.sml
1966 lines (1883 loc) · 84.8 KB
/
itree_semanticsEquivScript.sml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
Relating the itree- and FFI state-based CakeML semantics
*)
open HolKernel Parse boolLib bossLib BasicProvers dep_rewrite;
open optionTheory relationTheory pairTheory listTheory arithmeticTheory llistTheory;
open namespaceTheory astTheory ffiTheory lprefix_lubTheory semanticPrimitivesTheory
semanticsTheory evaluatePropsTheory smallStepTheory smallStepPropsTheory primSemEnvTheory;
open itreeTheory itree_semanticsTheory itree_semanticsPropsTheory;
val _ = new_theory "itree_semanticsEquiv";
(******************** Useful simplifications ********************)
(* Deliberately no `application_def` here *)
val smallstep_ss = simpLib.named_rewrites "smallstep_ss" [
smallStepTheory.continue_def,
smallStepTheory.return_def,
smallStepTheory.push_def,
smallStepTheory.e_step_def
];
val dsmallstep_ss = simpLib.named_rewrites "dsmallstep_ss" [
smallStepPropsTheory.collapse_env_def,
smallStepTheory.decl_continue_def,
smallStepTheory.decl_step_def
];
val itree_ss = simpLib.named_rewrites "itree_ss" [
itree_semanticsTheory.exn_continue_def,
itree_semanticsTheory.continue_def,
itree_semanticsTheory.return_def,
itree_semanticsTheory.push_def,
itree_semanticsTheory.estep_def,
get_ffi_def
];
val ditree_ss = simpLib.named_rewrites "ditree_ss" [
itree_semanticsTheory.dcontinue_def,
itree_semanticsTheory.dreturn_def,
itree_semanticsTheory.dpush_def,
itree_semanticsTheory.dstep_def,
dget_ffi_def
];
(******************** Simpler lemmas ********************)
Theorem do_app_cases =
``do_app st op vs = SOME (st',v)`` |> SIMP_CONV (srw_ss()) [
do_app_def, AllCaseEqs(), SF DNF_ss, LET_THM, GSYM DISJ_ASSOC];
Theorem do_app_rel:
(∀s. op ≠ FFI s) ⇒
OPTREL (λ(a,b) (c,d). a = c ∧ result_rel b d)
(do_app st op vs)
(OPTION_MAP (λ(a,b). (FST a, b)) (do_app (st, ffi) op vs))
Proof
rw[] >> reverse $ Cases_on `do_app (st,ffi) op vs` >> gvs[]
>- (
PairCases_on `x` >> gvs[semanticPrimitivesPropsTheory.do_app_cases] >>
simp[do_app_def, result_rel_cases] >> every_case_tac >> gvs[]
) >>
Cases_on `do_app st op vs` >> gvs[] >> PairCases_on `x` >>
gvs[do_app_cases, semanticPrimitivesTheory.do_app_def, store_alloc_def] >>
every_case_tac >> gvs[]
QED
Theorem ctxt_rel_fix_fp_state:
∀ fp cs1 cs2.
ctxt_rel cs1 cs2 ⇒
fix_fp_state cs1 fp = fix_fp_state cs2 fp
Proof
Induct_on ‘cs1’ >>
gs[ctxt_rel_def, fix_fp_state_def, smallStepTheory.fix_fp_state_def] >>
rpt strip_tac >> rpt VAR_EQ_TAC >>
Cases_on ‘h’ >> gs[] >>
Cases_on ‘y’ >> gs[] >> rpt VAR_EQ_TAC >>
qpat_x_assum ‘ctxt_frame_rel _ _’ mp_tac >>
Cases_on ‘q’ >> gs[] >> Cases_on ‘q'’ >>
simp[ctxt_frame_rel_cases, fix_fp_state_def, smallStepTheory.fix_fp_state_def]
QED
Theorem do_fprw_id:
result_rel r1 r2 ⇒
OPTREL result_rel (itree_semantics$do_fprw r1 opts rws)
(semanticPrimitives$do_fprw r2 opts rws)
Proof
Cases_on ‘r1’ >> Cases_on ‘r2’ >> gs[result_rel_cases] >> rw[OPTREL_def] >>
gs[do_fprw_def, semanticPrimitivesTheory.do_fprw_def] >>
every_case_tac >> gs[result_rel_cases]
QED
Theorem application_rel:
(∀s. op ≠ FFI s) ∧
ctxt_rel cs1 cs2 ⇒
step_result_rel
(application op env st fp vs cs1)
(application op env (st,ffi) fp vs cs2)
Proof
rw[] >>
drule do_app_rel >> disch_then $ qspecl_then [`vs`,`st`,`ffi`] assume_tac >>
Cases_on ‘getOpClass op’
>- (
Cases_on ‘op’ >> gs[getOpClass_def, application_def, cml_application_thm] >>
simp[step_result_rel_cases, AllCaseEqs(), PULL_EXISTS] >>
Cases_on ‘do_app (st,ffi) Eval vs’ >> gvs[] >>
Cases_on ‘do_app st Eval vs’ >> gvs[]
>- (
irule $ GSYM ctxt_rel_fix_fp_state >> simp[])>>
PairCases_on ‘x’ >> PairCases_on ‘x'’ >>
gvs[result_rel_cases, SF smallstep_ss, SF itree_ss] >>
gs[do_app_def, semanticPrimitivesTheory.do_app_def] >> every_case_tac >>
gs[])
>- (
rw[application_def, cml_application_thm] >>
simp[step_result_rel_cases, AllCaseEqs(), PULL_EXISTS] >>
Cases_on `do_opapp vs` >> simp[ctxt_rel_fix_fp_state] >>
PairCases_on `x` >> simp[]
)
>- (
rw[application_def, cml_application_thm] >>
Cases_on `do_app (st,ffi) op vs` >> gvs[] >>
Cases_on `do_app st op vs` >> gvs[]
>- (simp[step_result_rel_cases, AllCaseEqs()] >> Cases_on `op` >> gvs[ctxt_rel_fix_fp_state]) >>
PairCases_on `x` >> PairCases_on `x'` >> gvs[] >>
gvs[result_rel_cases, SF smallstep_ss, SF itree_ss] >>
simp[step_result_rel_cases, AllCaseEqs()] >>
qexists_tac `cs1` >> simp[] >> Cases_on `op` >> gvs[] >>
gs[do_app_def, semanticPrimitivesTheory.do_app_def] >> every_case_tac >> gs[store_alloc_def])
>- (
rw[application_def, cml_application_thm] >>
Cases_on `do_app (st,ffi) op vs` >> gvs[] >>
Cases_on `do_app st op vs` >> gvs[]
>- (simp[step_result_rel_cases, AllCaseEqs()] >> Cases_on `op` >> gvs[ctxt_rel_fix_fp_state]) >>
gs[step_result_rel_cases,ctxt_rel_fix_fp_state] >>
PairCases_on `x` >> PairCases_on `x'` >> gvs[] >>
imp_res_tac do_fprw_id >>
first_x_assum $ qspecl_then [‘fp.rws’, ‘fp.opts 0’] assume_tac >>
gvs[result_rel_cases, SF smallstep_ss, SF itree_ss] >>
simp[step_result_rel_cases, AllCaseEqs()]
>- (qexists_tac `cs1` >> simp[isFpBool_def] >> Cases_on `op` >> gvs[] >>
Cases_on ‘semanticPrimitives$do_fprw (Rval v) (fp.opts 0) fp.rws’ >> gs[] >>
TRY $ first_x_assum $ irule_at Any >> gs[OPTREL_def, result_rel_cases] >>
rpt VAR_EQ_TAC >|
[ Cases_on ‘v’,
Cases_on ‘v'’] >>
gs[do_fprw_def] >> every_case_tac >> gs[])
>- (
qexists_tac `cs1` >> simp[] >> Cases_on `op` >> gvs[] >>
gvs[ctxt_rel_def] >> simp[ctxt_frame_rel_cases] >>
gs[do_app_def, semanticPrimitivesTheory.do_app_def] >> every_case_tac >>
gs[store_alloc_def]
)
>- (qexists_tac `cs1` >> simp[isFpBool_def] >> Cases_on `op` >> gvs[] >>
gs[OPTREL_def, result_rel_cases] >> rpt VAR_EQ_TAC
>- (Cases_on ‘v’ >> gs[])
>- (Cases_on ‘v'’ >> gs[do_fprw_def] >> every_case_tac >> gs[]) >>
gs[do_fprw_def] >> every_case_tac >> gs[])
)
>- (
rw[application_def, cml_application_thm]
>- (
Cases_on `do_app (st,ffi) op vs` >> gvs[] >>
Cases_on `do_app st op vs` >> gvs[]
>- (simp[step_result_rel_cases, AllCaseEqs()] >> Cases_on `op` >> gvs[ctxt_rel_fix_fp_state]) >>
gs[step_result_rel_cases,ctxt_rel_fix_fp_state] >>
PairCases_on `x` >> PairCases_on `x'` >> gvs[] >>
gvs[result_rel_cases, SF smallstep_ss, SF itree_ss] >>
simp[step_result_rel_cases, AllCaseEqs()] >>
gvs[ctxt_rel_def] >> simp[ctxt_frame_rel_cases])
>- (gs[step_result_rel_cases, ctxt_rel_fix_fp_state]
))
QED
Theorem application_rel_FFI_type_error:
application (FFI s) env st fp vs cs1 = Etype_error (fix_fp_state cs1 fp) ⇔
application (FFI s) env (st, ffi) fp vs cs2 = Eabort (fix_fp_state cs2 fp, Rtype_error)
Proof
rw[application_def, cml_application_thm] >>
simp[semanticPrimitivesTheory.do_app_def] >>
every_case_tac >> gvs[SF smallstep_ss] >>
gvs[store_lookup_def, store_assign_def, store_v_same_type_def]
QED
Theorem application_rel_FFI_step:
application (FFI s) env st fp vs cs1 = Estep (env, st, fp2, Val v, cs1) ⇔
application (FFI s) env (st, ffi) fp vs cs2 = Estep (env, (st,ffi), fp2, Val v, cs2)
Proof
rw[application_def, cml_application_thm] >>
simp[semanticPrimitivesTheory.do_app_def] >>
every_case_tac >> gvs[SF smallstep_ss] >>
gvs[call_FFI_def, store_lookup_def, store_assign_def, store_v_same_type_def]
>- (eq_tac >> rw[] >> metis_tac[LUPDATE_SAME]) >>
every_case_tac >> gvs[] >> rw[] >> gvs[ffi_state_component_equality]
QED
Theorem dstep_ExpVal_Exp:
dstep env st (ExpVal env' (Exp e) cs locs p) dcs =
case estep (env',st.refs,st.fp_state,Exp e,cs) of
| Estep (env',refs',fp', ev',ec') =>
dreturn (st with <| refs := refs'; fp_state := fp' |>) dcs (ExpVal env' ev' ec' locs p)
| Effi s ws1 ws2 n env'' refs'' ec'' =>
Dffi (st with refs := refs'') (s,ws1,ws2,n,env'',ec'') locs p dcs
| Edone => Ddone
| Etype_error fp => Dtype_error fp
Proof
Cases_on `cs` >> rw[SF ditree_ss]
QED
Theorem decl_step_ExpVal_Exp:
decl_step env (st,ExpVal env' (Exp e) ec locs p,c) =
case e_step (env',(st.refs,st.ffi),st.fp_state,Exp e,ec) of
Estep (env',(refs',ffi'),fp',ev',ec') =>
Dstep
(st with <|refs := refs'; ffi := ffi'; fp_state := fp'|>,
ExpVal env' ev' ec' locs p,c)
| Eabort a => Dabort a
| Estuck => Ddone
Proof
rw[decl_step_def] >> TOP_CASE_TAC >> simp[] >>
rpt TOP_CASE_TAC >> gs[]
QED
(******************** Relating non-FFI steps ********************)
Triviality FST_THM:
FST = λ(x,y,z). x
Proof
rw[FUN_EQ_THM, UNCURRY]
QED
Theorem step_result_rel_single:
∀ea eb.
step_result_rel (Estep ea) (Estep eb) ∧
¬ is_Effi (estep ea)
⇒ step_result_rel (estep ea) (e_step eb) ∧
∀ffi. get_ffi (e_step eb) = SOME ffi ⇒ get_ffi (Estep eb) = SOME ffi
Proof
rpt PairCases >> rename1 `_ (_ (env,st,fp,ev,cs1)) (_ (env',(st',ffi),fp',ev',cs2))` >>
gvs[e_step_def] >> reverse $ TOP_CASE_TAC >> gvs[]
>- (
simp[Once step_result_rel_cases] >> strip_tac >> gvs[] >>
TOP_CASE_TAC >> gvs[]
>- (gvs[ctxt_rel_def, SF smallstep_ss, SF itree_ss, step_result_rel_cases]) >>
TOP_CASE_TAC >> gvs[] >> TOP_CASE_TAC >> gvs[] >>
gvs[ctxt_rel_def] >> gvs[GSYM ctxt_rel_def] >> gvs[ctxt_frame_rel_cases] >>
pairarg_tac >> gvs[SF smallstep_ss, SF itree_ss, step_result_rel_cases] >>
simp[ctxt_rel_def] >> simp[GSYM ctxt_rel_def] >> simp[ctxt_frame_rel_cases]
)
>- (
gvs[estep_def, step_result_rel_cases] >> strip_tac >>
gvs[SF smallstep_ss, SF itree_ss, ctxt_rel_def, ctxt_frame_rel_cases, get_ffi_def] >>
gvs[GSYM ctxt_frame_rel_cases, GSYM step_result_rel_cases] >>
CASE_TAC >- gvs[continue_def, get_ffi_def] >>
PairCases_on `h` >> gvs[] >> PairCases_on `x` >> gvs[] >>
rename1 `ctxt_frame_rel c1 c2` >> rename1 `(c1,env)` >>
rename1 `LIST_REL _ rest1 rest2` >>
Cases_on `c1` >> gvs[SF itree_ss, ctxt_frame_rel_cases] >>
gvs[GSYM ctxt_frame_rel_cases, get_ffi_def]
>- (
reverse CASE_TAC >>
gvs[PULL_EXISTS, EXISTS_PROD, get_ffi_def, SF itree_ss]
>- simp[ctxt_frame_rel_cases] >>
rename1 `application op _ _ _ vs _` >>
reverse $ Cases_on `∃s. op = FFI s` >> gvs[]
>- (
reverse $ rw[]
>- (
drule application_ffi_unchanged >>
Cases_on `application op env (st,ffi) fp vs rest2` >> gvs[get_ffi_def] >>
PairCases_on `p` >> disch_then drule >> gvs[get_ffi_def]
)
>- (
drule application_rel >> gvs[ctxt_rel_def] >> disch_then drule >>
disch_then $ qspecl_then [`vs`,`st`,‘fp’,`ffi`,`env`] assume_tac >>
gvs[step_result_rel_cases, ctxt_rel_def]
)
) >>
qspecl_then [`vs`,`st`,`s`,‘fp’,`env`,`rest1`]
assume_tac $ GEN_ALL application_FFI_results >> gvs[] >>
csimp[] >> gvs[is_Effi_def, get_ffi_def]
>- (imp_res_tac $ SIMP_RULE std_ss [ctxt_rel_def] ctxt_rel_fix_fp_state >>
metis_tac[application_rel_FFI_type_error]) >>
imp_res_tac application_rel_FFI_step >> gvs[get_ffi_def]
)
>- (EVERY_CASE_TAC >> gvs[get_ffi_def, ctxt_frame_rel_cases] >>
irule $ GSYM ctxt_rel_fix_fp_state >> gs[ctxt_rel_def, ctxt_frame_rel_cases])
>- (EVERY_CASE_TAC >> gvs[get_ffi_def, ctxt_frame_rel_cases] >>
irule $ GSYM ctxt_rel_fix_fp_state >> gs[ctxt_rel_def, ctxt_frame_rel_cases])
>- (EVERY_CASE_TAC >> gvs[get_ffi_def, ctxt_frame_rel_cases] >>
irule $ GSYM ctxt_rel_fix_fp_state >> gs[ctxt_rel_def, ctxt_frame_rel_cases])
>- (
CASE_TAC >> simp[SF itree_ss] >>
PairCases_on `h` >> simp[continue_def] >>
EVERY_CASE_TAC >> gvs[get_ffi_def, ctxt_frame_rel_cases] >>
irule $ GSYM ctxt_rel_fix_fp_state >> gs[ctxt_rel_def, ctxt_frame_rel_cases])
>- (
TOP_CASE_TAC >> gvs[SF itree_ss] >>
EVERY_CASE_TAC >> gvs[get_ffi_def, ctxt_frame_rel_cases] >>
irule $ GSYM ctxt_rel_fix_fp_state >> gs[ctxt_rel_def, ctxt_frame_rel_cases]
)
)
>- (
reverse $ every_case_tac >> gvs[estep_def, step_result_rel_cases] >> strip_tac >>
gvs[SF smallstep_ss, SF itree_ss, ctxt_rel_def, ctxt_frame_rel_cases, get_ffi_def] >>
gvs[GSYM ctxt_frame_rel_cases, GSYM step_result_rel_cases]
>- gvs[FST_THM, LAMBDA_PROD] >>
TRY (gvs[FST_THM, LAMBDA_PROD] >>
irule ctxt_rel_fix_fp_state >> gs[ctxt_rel_def, ctxt_frame_rel_cases] >> NO_TAC) >>
TRY (irule ctxt_rel_fix_fp_state >> gs[ctxt_rel_def] >> NO_TAC) >>
rename1 `application op _ _ _ _ _` >>
reverse $ Cases_on `∃s. op = FFI s` >> gvs[]
>- (
reverse $ rw[]
>- (
drule application_ffi_unchanged >>
Cases_on `application op env (st,ffi) fp [] cs2` >> gvs[get_ffi_def] >>
PairCases_on `p` >> disch_then drule >> gvs[get_ffi_def]
)
>- (
drule application_rel >> gvs[ctxt_rel_def] >> disch_then drule >>
disch_then $ qspecl_then [`[]`,`st`,‘fp’,`ffi`,`env`] assume_tac >>
gvs[step_result_rel_cases, ctxt_rel_def]
)
)
>- (
qspecl_then [`[]`,`st`,`s`,‘fp’,`env`,`cs1`]
assume_tac $ GEN_ALL application_FFI_results >> gvs[] >>
csimp[] >> gvs[is_Effi_def, get_ffi_def]
>- (imp_res_tac application_rel_FFI_type_error >> gs[] >>
irule $ GSYM ctxt_rel_fix_fp_state >> gs[ctxt_rel_def]) >>
imp_res_tac application_rel_FFI_step >> simp[get_ffi_def]
)
>- (
reverse $ rw[]
>- (
drule application_ffi_unchanged >>
Cases_on `application op env (st,ffi) fp [] cs2` >> gvs[get_ffi_def] >>
PairCases_on `p` >> disch_then drule >> gvs[get_ffi_def]
)
>- (
drule application_rel >> gvs[ctxt_rel_def] >> disch_then drule >>
disch_then $ qspecl_then [`[]`,`st`,‘fp’,`ffi`,`env`] assume_tac >>
gvs[step_result_rel_cases, ctxt_rel_def]
)
)
>- (
qspecl_then [`[]`,`st`,`s`,‘fp’,`env`,`cs1`]
assume_tac $ GEN_ALL application_FFI_results >> gvs[] >>
csimp[] >> gvs[is_Effi_def, get_ffi_def]
>- (imp_res_tac application_rel_FFI_type_error >> gs[] >>
irule $ GSYM ctxt_rel_fix_fp_state >> gs[ctxt_rel_def]) >>
imp_res_tac application_rel_FFI_step >> simp[get_ffi_def]
))
QED
Theorem is_Dffi_eq_is_Effi_single:
is_Dffi (dstep env dsta (ExpVal env' ev cs l p) dcs) ⇔
is_Effi (estep (env',dsta.refs,dsta.fp_state,ev,cs))
Proof
Cases_on `ev` >> rw[SF ditree_ss, SF itree_ss] >>
Cases_on `cs` >> rw[SF ditree_ss, SF itree_ss, is_Effi_def, is_Dffi_def] >>
every_case_tac >> gvs[is_Effi_def, is_Dffi_def]
QED
Theorem dstep_result_rel_single:
∀dsta deva dcsa db env.
dstep_result_rel (Dstep dsta deva dcsa) (Dstep db) ∧
¬is_Dffi (dstep env dsta deva dcsa)
⇒ dstep_result_rel (dstep env dsta deva dcsa) (decl_step env db) ∧
∀ffi. dget_ffi (decl_step env db) = SOME ffi ⇒ dget_ffi (Dstep db) = SOME ffi
Proof
ntac 3 gen_tac >> PairCases >> gen_tac >>
simp[Once dstep_result_rel_cases] >> strip_tac >> gvs[deval_rel_cases]
>- (
Cases_on `d` >> gvs[decl_step_def, dstep_def] >>
every_case_tac >> gvs[FST_THM, LAMBDA_PROD] >>
simp[dstep_result_rel_cases, deval_rel_cases, ctxt_rel_def] >>
gvs[dstate_rel_def, dget_ffi_def]
)
>- (
Cases_on `db2` >> gvs[SF dsmallstep_ss, SF ditree_ss]
>- simp[dstep_result_rel_cases] >>
Cases_on `h` >> gvs[SF dsmallstep_ss, SF ditree_ss] >>
Cases_on `l` >> gvs[SF dsmallstep_ss, SF ditree_ss] >>
simp[dstep_result_rel_cases, deval_rel_cases, dget_ffi_def]
) >>
Cases_on `ev` >> gvs[]
>- (
`¬is_Effi (estep (env',dsta.refs,dsta.fp_state,Exp e,cs))` by gvs[is_Dffi_eq_is_Effi_single] >>
simp[dstep_ExpVal_Exp, decl_step_ExpVal_Exp] >>
drule_at Any step_result_rel_single >>
simp[Once step_result_rel_cases, PULL_EXISTS] >>
disch_then drule >> disch_then $ qspec_then `db0.ffi` assume_tac >>
rgs[dstate_rel_def, get_ffi_def] >>
pop_assum mp_tac >> rw[step_result_rel_cases] >> gvs[dget_ffi_def, get_ffi_def] >>
simp[dstep_result_rel_cases, deval_rel_cases, dstate_rel_def]
)
>- (
Cases_on `cs` >> gvs[]
>- (
gvs[ctxt_rel_def, SF dsmallstep_ss, SF ditree_ss, dstate_rel_def] >>
every_case_tac >> gvs[] >>
gvs[dstep_result_rel_cases, deval_rel_cases, dstate_rel_def, dget_ffi_def]
) >>
gvs[ctxt_rel_def] >> gvs[GSYM ctxt_rel_def] >>
pairarg_tac >> gvs[] >> pairarg_tac >> gvs[] >>
gvs[is_Dffi_eq_is_Effi_single] >>
drule_at Any step_result_rel_single >> simp[FORALL_PROD] >>
simp[step_result_rel_cases, ctxt_rel_def] >>
simp[GSYM ctxt_rel_def, PULL_EXISTS, FORALL_PROD] >> disch_then drule_all >>
disch_then $ qspec_then `db0.ffi` mp_tac >> rw[] >> gvs[] >>
gvs[SF dsmallstep_ss, SF ditree_ss] >>
gvs[dstate_rel_def, dget_ffi_def, get_ffi_def] >>
gvs[dstep_result_rel_cases, dstate_rel_def, deval_rel_cases, ctxt_rel_def]
)
>- (
Cases_on `cs` >> gvs[]
>- (
gvs[ctxt_rel_def, SF dsmallstep_ss, SF ditree_ss, dstate_rel_def] >>
gvs[dstep_result_rel_cases]
) >>
gvs[ctxt_rel_def] >> gvs[GSYM ctxt_rel_def] >>
pairarg_tac >> gvs[] >> pairarg_tac >> gvs[] >>
gvs[is_Dffi_eq_is_Effi_single] >>
drule_at Any step_result_rel_single >> simp[FORALL_PROD] >>
simp[step_result_rel_cases, ctxt_rel_def] >>
simp[GSYM ctxt_rel_def, PULL_EXISTS, FORALL_PROD] >> disch_then drule_all >>
disch_then $ qspec_then `db0.ffi` mp_tac >> rw[] >> gvs[] >>
gvs[SF dsmallstep_ss, SF ditree_ss] >>
gvs[dstate_rel_def, dget_ffi_def, get_ffi_def] >>
gvs[dstep_result_rel_cases, dstate_rel_def, deval_rel_cases, ctxt_rel_def]
)
QED
Theorem dstep_result_rel_n:
∀n dsta deva dcsa db env.
dstep_result_rel (Dstep dsta deva dcsa) (Dstep db) ∧
¬ is_Dffi (step_n env n (Dstep dsta deva dcsa))
⇒ dstep_result_rel
(step_n env n (Dstep dsta deva dcsa)) (step_n_cml env n (Dstep db))∧
∀ffi. dget_ffi (step_n_cml env n (Dstep db)) = SOME ffi
⇒ dget_ffi (Dstep db) = SOME ffi
Proof
Induct >- simp[step_n_def, step_n_cml_def] >>
simp[step_n_alt_def, step_n_cml_alt_def] >>
rpt gen_tac >> strip_tac >>
last_x_assum drule >> disch_then $ qspec_then `env` mp_tac >>
impl_tac >- (every_case_tac >> gvs[is_Dffi_def]) >> strip_tac >>
imp_res_tac dstep_result_rel_cases >> gvs[dget_ffi_def] >>
drule dstep_result_rel_single >> disch_then $ qspec_then `env` mp_tac >>
simp[] >> rw[] >> gvs[dget_ffi_def]
QED
(******************** Relating FFI steps ********************)
Theorem estep_to_Effi:
estep ea = Effi (ExtCall s) conf ws lnum env st cs ⇔
∃env' conf' fp' b.
conf = MAP (λc. n2w (ORD c)) (EXPLODE conf') ∧
ea = (env',st,fp',Val (Litv (StrLit conf')),
(Capp (FFI s) [Loc b lnum] [],env)::cs) ∧
store_lookup lnum st = SOME (W8array ws) ∧ s ≠ ""
Proof
PairCases_on `ea` >> Cases_on `ea3` >> gvs[SF itree_ss]
>- (
Cases_on `e` >> gvs[SF itree_ss] >> every_case_tac >> gvs[] >>
simp[application_thm] >> every_case_tac >> gvs[SF itree_ss]
) >>
Cases_on `ea4` >> gvs[SF itree_ss] >>
PairCases_on `h` >> reverse $ Cases_on `h0` >> gvs[SF itree_ss] >>
every_case_tac >> gvs[]
>- (Cases_on `l0` >> gvs[SF itree_ss] >> every_case_tac >> gvs[])
>- (
Cases_on `l` >> gvs[SF itree_ss] >>
Cases_on `h` >> gvs[SF itree_ss] >> every_case_tac >> gvs[]
) >>
Cases_on `l0` >> gvs[SF itree_ss] >> reverse eq_tac >> rw[]
>- simp[application_thm] >>
drule application_eq_Effi_fields >> rw[] >>
gvs[application_thm] >> every_case_tac >> gvs[]
QED
Theorem dstep_to_Dffi:
dstep env dst dev dcs =
Dffi dst' (ExtCall s,ws1,ws2,lnum,env',cs) locs pat dcs' ⇔
∃env'' conf b.
dst = dst' ∧ dcs = dcs' ∧
dev = ExpVal env'' (Val (Litv (StrLit conf)))
((Capp (FFI s) [Loc b lnum] [],env')::cs) locs pat ∧
ws1 = MAP (λc. n2w (ORD c)) (EXPLODE conf) ∧
store_lookup lnum dst.refs = SOME (W8array ws2) ∧ s ≠ ""
Proof
Cases_on `∃d. dev = Decl d` >> gvs[dstep_def]
>- (Cases_on `d` >> gvs[dstep_def] >> every_case_tac >> gvs[]) >>
Cases_on `∃e. dev = Env e` >> gvs[dstep_def]
>- (
Cases_on `dcs` >> gvs[SF ditree_ss] >>
Cases_on `h` >> Cases_on `l` >> gvs[SF ditree_ss]
) >>
Cases_on `dev` >> gvs[SF ditree_ss] >> rw[] >> reverse eq_tac >> rw[]
>- simp[SF ditree_ss, SF itree_ss, application_thm, dstate_component_equality] >>
`is_Dffi (dstep env dst (ExpVal s' e l l0 p) dcs)` by gvs[is_Dffi_def] >>
gvs[is_Dffi_eq_is_Effi_single, is_Effi_def, estep_to_Effi] >>
rw[] >> gvs[SF ditree_ss, SF itree_ss, application_thm] >>
simp[dstate_component_equality]
QED
Theorem decl_step_ffi_changed_dstep_to_Dffi:
decl_step env (dst2, dev2, dcs) = Dstep (dst2', dev2', dcs') ∧
dst2.ffi ≠ dst2'.ffi ∧
dstate_rel dst1 dst2 ∧ deval_rel dev1 dev2 ⇒
∃env' env'' conf s lnum ccs locs pat ws b.
dev1 = ExpVal env' (Val $ Litv $ StrLit conf)
((Capp (FFI s) [Loc b lnum] [], env'') :: ccs) locs pat ∧
store_lookup lnum dst1.refs = SOME (W8array ws) ∧
dstep env dst1 dev1 dcs = Dffi dst1
(ExtCall s,MAP (λc. n2w $ ORD c) (EXPLODE conf),ws,lnum,env'',ccs)
locs pat dcs'
Proof
rw[] >> drule_all decl_step_ffi_changed >> rw[] >>
gvs[deval_rel_cases, ctxt_rel_def, dstate_rel_def] >>
pairarg_tac >> gvs[GSYM ctxt_rel_def, ctxt_frame_rel_cases] >>
gvs[SF ditree_ss, SF itree_ss] >>
simp[application_thm, dstate_component_equality] >>
gvs[SF dsmallstep_ss, SF smallstep_ss, cml_application_thm] >>
gvs[semanticPrimitivesTheory.do_app_def, ffiTheory.call_FFI_def] >>
gvs[store_assign_def, store_lookup_def, store_v_same_type_def]
QED
Theorem dstep_result_rel_single_FFI:
∀dsta deva dcsa db env dsta' s ws1 ws2 n env' cs ffi_call locs pat dcsa'.
dstep_result_rel (Dstep dsta deva dcsa) (Dstep db) ∧
dstep env dsta deva dcsa =
Dffi dsta' (ExtCall s,ws1,ws2,n,env',cs) locs pat dcsa'
⇒ ∃ffi.
dget_ffi (Dstep db) = SOME ffi ∧
((∃ffi'. dget_ffi (decl_step env db) = SOME ffi' ∧ ffi' ≠ ffi) ∨
(∃outcome fp.
decl_step env db =
Dabort (fp, (Rffi_error $ Final_event (ExtCall s) ws1 ws2 outcome))))
Proof
ntac 3 gen_tac >> PairCases >> rw[] >>
gvs[dstep_result_rel_cases, dstep_to_Dffi, dget_ffi_def] >>
gvs[deval_rel_cases, ctxt_rel_def] >>
gvs[GSYM ctxt_rel_def, ctxt_frame_rel_cases] >> pairarg_tac >> gvs[] >>
simp[SF dsmallstep_ss, SF smallstep_ss, cml_application_thm] >>
simp[semanticPrimitivesTheory.do_app_def, ffiTheory.call_FFI_def] >>
every_case_tac >> gvs[dget_ffi_def] >>
gvs[store_lookup_def, store_assign_def, store_v_same_type_def, dstate_rel_def] >>
rw[ffi_state_component_equality] >>
simp[combinTheory.o_DEF, stringTheory.IMPLODE_EXPLODE_I]
QED
Theorem step_result_rel_single_FFI_error:
∀ea eb.
step_result_rel (Estep ea) (Estep eb) ∧
e_step eb = Eabort (fp, (Rffi_error (Final_event s conf ws outcome)))
⇒ ∃lnum env. estep ea =
Effi s conf ws lnum env (FST $ SND ea) (TL $ SND $ SND $ SND $ SND ea)
Proof
rpt $ PairCases >> rw[e_step_def] >> gvs[AllCaseEqs(), SF smallstep_ss] >>
gvs[cml_application_thm, AllCaseEqs(), SF smallstep_ss] >>
gvs[semanticPrimitivesPropsTheory.do_app_cases, AllCaseEqs()] >>
gvs[step_result_rel_cases, ctxt_rel_def] >>
gvs[GSYM ctxt_rel_def, ctxt_frame_rel_cases] >> pairarg_tac >> gvs[] >>
simp[SF itree_ss, application_def] >> gvs[call_FFI_def, AllCaseEqs()] >>
gs[semanticPrimitivesTheory.do_fprw_def] >> every_case_tac >> gs[] >>
simp[combinTheory.o_DEF, stringTheory.IMPLODE_EXPLODE_I]
QED
Theorem dstep_result_rel_single_FFI_strong:
∀dsta deva dcsa dstb devb dcsb env dsta' s conf ws lnum eenv cs1 locs pat
dcsa'.
dstep_result_rel (Dstep dsta deva dcsa) (Dstep (dstb, devb, dcsb)) ∧
dstep env dsta deva dcsa =
Dffi dsta' (ExtCall s,conf,ws,lnum,eenv,cs1) locs pat dcsa'
⇒ ∃env' ffi conf' cs2 fp b.
conf = MAP (λc. n2w (ORD c)) (EXPLODE conf') ∧
deva = ExpVal env' (Val (Litv $ StrLit conf'))
((Capp (FFI s) [Loc b lnum] [], eenv)::cs1) locs pat ∧
devb = ExpVal env' (Val (Litv $ StrLit conf'))
((Capp (FFI s) [Loc b lnum] () [], eenv)::cs2) locs pat ∧
store_lookup lnum dsta.refs = SOME (W8array ws) ∧ s ≠ "" ∧
dget_ffi (Dstep (dstb, devb, dcsb)) = SOME ffi ∧
decl_step env (dstb, devb, dcsb) =
case ffi.oracle (ExtCall s) ffi.ffi_state conf ws of
| Oracle_return ffi' ws' =>
if LENGTH ws' ≠ LENGTH ws then
Dabort (fp,
Rffi_error $ Final_event (ExtCall s) conf ws FFI_failed)
else
Dstep (
dstb with <|
refs := LUPDATE (W8array ws') lnum dstb.refs;
ffi := dstb.ffi with <|
ffi_state := ffi';
io_events := dstb.ffi.io_events ++
[IO_event (ExtCall s) conf (ZIP (ws,ws'))]
|>
|>,
ExpVal eenv (Val $ Conv NONE []) cs2 locs pat, dcsb)
| Oracle_final outcome =>
Dabort (fp, Rffi_error $ Final_event (ExtCall s) conf ws outcome)
Proof
rw[] >> gvs[dstep_to_Dffi, dstep_result_rel_cases, deval_rel_cases, ctxt_rel_def] >>
gvs[GSYM ctxt_rel_def, ctxt_frame_rel_cases] >> pairarg_tac >> gvs[] >>
simp[dget_ffi_def, SF dsmallstep_ss, SF smallstep_ss, cml_application_thm] >>
simp[semanticPrimitivesTheory.do_app_def, ffiTheory.call_FFI_def] >>
gvs[dstate_rel_def] >> every_case_tac >> gvs[] >>
gvs[store_assign_def, store_lookup_def, store_v_same_type_def,
semanticPrimitivesTheory.state_component_equality] >>
gvs[combinTheory.o_DEF, stringTheory.IMPLODE_EXPLODE_I]
QED
Theorem dstep_result_rel_single_FFI_error:
∀dsta deva dcsa dstb devb dcsb.
dstep_result_rel (Dstep dsta deva dcsa) (Dstep (dstb,devb,dcsb)) ∧
decl_step env (dstb,devb,dcsb) =
Dabort (fp, (Rffi_error (Final_event (ExtCall s) conf ws outcome)))
⇒ ∃lnum env' cs locs pat.
dstep env dsta deva dcsa =
Dffi dsta (ExtCall s,conf,ws,lnum,env',cs) locs pat dcsa
Proof
rw[] >> Cases_on `∃d. deva = Decl d` >> gvs[]
>- (
gvs[dstep_result_rel_cases, deval_rel_cases] >>
Cases_on `d` >> gvs[SF dsmallstep_ss, SF ditree_ss] >>
every_case_tac >> gvs[]
) >>
Cases_on `∃e. deva = Env e` >> gvs[]
>- (
gvs[dstep_result_rel_cases, deval_rel_cases] >>
Cases_on `e` >> gvs[SF dsmallstep_ss, SF ditree_ss] >>
every_case_tac >> gvs[]
) >>
Cases_on `deva` >> gvs[dstep_result_rel_cases, deval_rel_cases] >>
gvs[SF dsmallstep_ss] >>
qmatch_asmsub_abbrev_tac `e_step_result_CASE foo` >>
qspec_then `(s',(dstb.refs,dstb.ffi),dstb.fp_state,e,scs)` mp_tac $
(step_result_rel_single_FFI_error
|> Q.INST [‘s’ |-> ‘ExtCall ss’]
|> Q.INST [‘ss’ |-> ‘s’]
|> SIMP_RULE std_ss [Once SWAP_FORALL_THM]) >>
simp[step_result_rel_cases, PULL_EXISTS] >> disch_then drule >>
simp[estep_to_Effi] >> strip_tac >> unabbrev_all_tac >>
Cases_on `e` >> gvs[] >- (every_case_tac >> gvs[]) >>
Cases_on `scs` >> gvs[ctxt_rel_def] >- (every_case_tac >> gvs[]) >>
gvs[GSYM ctxt_rel_def, ctxt_frame_rel_cases] >>
pairarg_tac >> gvs[] >> pairarg_tac >> gvs[] >>
every_case_tac >> gvs[] >>
gvs[SF ditree_ss, SF itree_ss, application_thm, dstate_rel_def] >>
simp[dstate_component_equality]
QED
Theorem dstep_result_rel_single':
∀dsta deva dcsa d2 env.
(∀ffi. dget_ffi (decl_step env d2) = SOME ffi ⇒ dget_ffi (Dstep d2) = SOME ffi) ∧
(∀a fp. decl_step env d2 ≠ Dabort (fp, Rffi_error a)) ∧
dstep_result_rel (Dstep dsta deva dcsa) (Dstep d2)
⇒ dstep_result_rel (dstep env dsta deva dcsa) (decl_step env d2)
Proof
rw[] >> drule dstep_result_rel_single >> rw[] >>
gvs[IMP_CONJ_THM, FORALL_AND_THM] >>
first_x_assum irule >> CCONTR_TAC >> gvs[is_Dffi_def] >>
PairCases_on `ev0` >> drule_all dstep_result_rel_single_FFI >> rw[] >> gvs[]
QED
Theorem dstep_result_rel_n':
∀n dsta deva dcsa db env.
dget_ffi (step_n_cml env n (Dstep db)) = dget_ffi (Dstep db) ∧
dstep_result_rel (Dstep dsta deva dcsa) (Dstep db)
⇒ dstep_result_rel
(step_n env n (Dstep dsta deva dcsa)) (step_n_cml env n (Dstep db))
Proof
Induct >- rw[step_n_def, step_n_cml_def] >> rw[] >>
`dstep_result_rel
(step_n env n (Dstep dsta deva dcsa)) (step_n_cml env n (Dstep db))` by (
last_x_assum irule >> simp[] >>
qspecl_then [`SUC n`,`Dstep db`] mp_tac step_n_cml_preserved_FFI >>
Cases_on `step_n_cml env (SUC n) (Dstep db)` >> gvs[dget_ffi_def] >>
PairCases_on `db` >> gvs[dget_ffi_def]) >>
simp[step_n_alt_def, step_n_cml_alt_def] >>
rgs[dstep_result_rel_cases] >> gvs[] >>
gvs[GSYM dstep_result_rel_cases, PULL_EXISTS, dget_ffi_def] >>
qspecl_then [`SUC n`,`Dstep (st',dev2',dcsa)`]
mp_tac step_n_cml_preserved_FFI >>
gvs[step_n_cml_alt_def] >>
Cases_on `decl_step env (st,dev2,dcs)` >> gvs[dget_ffi_def] >>
disch_then $ qspecl_then [`p`,`env`] mp_tac >> simp[] >>
disch_then $ qspec_then `n` mp_tac >> simp[dget_ffi_def] >> rw[] >> gvs[] >>
qpat_assum `decl_step _ _ = _` $ once_rewrite_tac o single o GSYM >>
irule dstep_result_rel_single' >>
simp[dget_ffi_def, dstep_result_rel_cases]
QED
(******************** interp ********************)
Theorem st_fp_state_st[local,simp]:
st with fp_state := st.fp_state = (st:'a semanticPrimitives$state)
Proof
gs[semanticPrimitivesTheory.state_component_equality]
QED
Theorem interp_Ret_Termination:
dstate_rel dst st ∧ deval_rel deva devb ⇒
(
interp env (Dstep dst deva dcs) = Ret Termination ⇔
(∃v st'. small_eval_dec env (st,devb,dcs) (st', Rval v) ∧ st.ffi = st'.ffi) ∨
(∃v st'. small_eval_dec env (st,devb,dcs) (st', Rerr (Rraise v)) ∧ st.ffi = st'.ffi)
)
Proof
rw[Once interp] >> eq_tac >> rw[]
>- (
every_case_tac >> gvs[step_until_halt_def] >>
pop_assum mp_tac >> DEEP_INTRO_TAC some_intro >> rw[] >> gvs[] >>
every_case_tac >> gvs[is_halt_def]
>- (
Induct_on `x` >> gvs[step_n_alt_def] >>
reverse every_case_tac >> gvs[] >- metis_tac[] >- metis_tac[] >>
rw[dstep_to_Ddone] >> disj1_tac >>
rw[small_eval_dec_eq_step_n_cml, PULL_EXISTS] >>
qspecl_then [`x`,`dst`,`deva`,`dcs`,`(st,devb,dcs)`,`env`]
assume_tac dstep_result_rel_n >>
gvs[is_Dffi_def, dstep_result_rel_cases, deval_rel_cases] >>
goal_assum drule >> gvs[dget_ffi_def]
)
>- (
Induct_on `x` >> gvs[step_n_alt_def] >>
every_case_tac >> gvs[] >> rw[] >>
rw[small_eval_dec_eq_step_n_cml, PULL_EXISTS] >> disj2_tac >>
qspecl_then [`x`,`dst`,`deva`,`dcs`,`(st,devb,dcs)`,`env`]
assume_tac dstep_result_rel_n >>
gvs[is_Dffi_def, dstep_result_rel_cases] >>
qspecl_then [`d`,`d0`,`l`,`(st',dev2,l)`,`env`]
assume_tac dstep_result_rel_single >>
gvs[is_Dffi_def, dstep_result_rel_cases, dget_ffi_def] >>
PairCases_on ‘p’ >> qexists_tac ‘p1’ >>
qexists_tac ‘st' with fp_state := p0’ >> gs[] >>
qexists_tac ‘x’ >> qexists_tac ‘dev2’ >> qexists_tac ‘l’ >>
qexists_tac ‘st'.fp_state’ >> gs[]
)
)
>- (
gvs[small_eval_dec_eq_step_n_cml, step_until_halt_def] >>
qspecl_then [`n`,`dst`,`deva`,`dcs`,`(st,devb,dcs)`,`env`]
assume_tac dstep_result_rel_n >>
gvs[dstep_result_rel_cases, dget_ffi_def] >>
pop_assum mp_tac >> impl_tac
>- (
irule dstep_result_rel_not_Dffi >> irule_at Any dstep_result_rel_n' >>
qexists_tac `(st,devb,dcs)` >> simp[dget_ffi_def, dstep_result_rel_cases]
) >>
strip_tac >> pop_assum mp_tac >> rw[deval_rel_cases] >>
DEEP_INTRO_TAC some_intro >> reverse $ rw[]
>- (qexists_tac `SUC n` >> simp[step_n_alt_def, SF ditree_ss, is_halt_def]) >>
`step_n env x (Dstep dst deva dcs) = step_n env (SUC n) (Dstep dst deva dcs)` by (
irule is_halt_step_n_eq >> simp[step_n_alt_def, SF ditree_ss, is_halt_def]) >>
gvs[step_n_alt_def, SF ditree_ss]
)
>- (
gvs[small_eval_dec_eq_step_n_cml, step_until_halt_def] >>
qspecl_then [`n`,`dst`,`deva`,`dcs`,`(st,devb,dcs)`,`env`]
assume_tac dstep_result_rel_n >>
gvs[dstep_result_rel_cases, dget_ffi_def] >>
pop_assum mp_tac >> impl_tac
>- (
irule dstep_result_rel_not_Dffi >> irule_at Any dstep_result_rel_n' >>
qexists_tac `(st,devb,dcs)` >> simp[dget_ffi_def, dstep_result_rel_cases]
) >>
strip_tac >>
qspecl_then [`dst'`,`dev1`,`dcs'`,`(st' with fp_state := fp,dev,dcs')`,`env`]
assume_tac dstep_result_rel_single' >>
gvs[dget_ffi_def, dstep_result_rel_cases] >>
DEEP_INTRO_TAC some_intro >> reverse $ rw[]
>- (qexists_tac `SUC n` >> simp[step_n_alt_def, SF ditree_ss, is_halt_def]) >>
`step_n env x (Dstep dst deva dcs) = step_n env (SUC n) (Dstep dst deva dcs)` by (
irule is_halt_step_n_eq >> simp[step_n_alt_def, SF ditree_ss, is_halt_def]) >>
gvs[step_n_alt_def, SF ditree_ss]
)
QED
Theorem interp_Ret_Error:
dstate_rel dst st ∧ deval_rel deva devb ⇒
(
interp env (Dstep dst deva dcs) = Ret Error ⇔
∃st'. small_eval_dec env (st,devb,dcs) (st',Rerr $ Rabort Rtype_error) ∧
st.ffi = st'.ffi
)
Proof
rw[Once interp] >> eq_tac >> rw[]
>- (
every_case_tac >> gvs[step_until_halt_def] >>
pop_assum mp_tac >> DEEP_INTRO_TAC some_intro >> rw[] >>
every_case_tac >> gvs[is_halt_def] >>
simp[small_eval_dec_eq_step_n_cml, PULL_EXISTS] >>
qspecl_then [`x`,`env`,`Dstep dst deva dcs`]
assume_tac is_halt_step_n_min >>
gvs[is_halt_def] >> qpat_x_assum `step_n _ x _ = _` kall_tac >>
Cases_on `m` >> gvs[step_n_alt_def] >>
reverse every_case_tac >> gvs[]
>- (first_x_assum $ qspec_then `n` mp_tac >> simp[is_halt_def]) >>
qspecl_then [`n`,`dst`,`deva`,`dcs`,`(st,devb,dcs)`,`env`]
assume_tac dstep_result_rel_n >>
gvs[dstep_result_rel_cases, is_Dffi_def] >>
qspecl_then [`d`,`d0`,`l`,`(st',dev2,l)`,`env`]
assume_tac dstep_result_rel_single >>
gvs[dstep_result_rel_cases, is_Dffi_def, dget_ffi_def] >>
qexists_tac ‘st' with fp_state := f’ >> gs[] >>
qexists_tac ‘n’ >> qexists_tac ‘dev2’ >> qexists_tac ‘l’ >>
qexists_tac ‘st'.fp_state’ >> gs[]
)
>- (
gvs[small_eval_dec_eq_step_n_cml] >>
qspecl_then [`n`,`dst`,`deva`,`dcs`,`(st,devb,dcs)`,`env`]
assume_tac dstep_result_rel_n' >>
gvs[dstep_result_rel_cases, is_Dffi_def, dget_ffi_def] >>
qspecl_then [`dst'`,`dev1`,`dcs'`,`(st' with fp_state := fp,dev,dcs')`,`env`]
assume_tac dstep_result_rel_single' >>
gvs[dstep_result_rel_cases, dget_ffi_def] >>
simp[step_until_halt_def] >> DEEP_INTRO_TAC some_intro >> reverse $ rw[]
>- (qexists_tac `SUC n` >> simp[step_n_alt_def, is_halt_def]) >>
`step_n env x (Dstep dst deva dcs) = step_n env (SUC n) (Dstep dst deva dcs)` by (
irule is_halt_step_n_eq >> simp[step_n_alt_def, is_halt_def]) >>
gvs[step_n_alt_def]
)
QED
Theorem interp_Div:
dstate_rel dst st ∧ deval_rel deva devb ⇒
(
interp env (Dstep dst deva dcs) = Div ⇔
∀n. ∃st2.
step_n_cml env n (Dstep (st,devb,dcs)) = Dstep st2 ∧
¬is_halt_cml (Dstep st2) ∧
dget_ffi (Dstep st2) = SOME st.ffi
)
Proof
rw[Once interp] >> eq_tac >> rw[]
>- (
gvs[step_until_halt_def] >> every_case_tac >> gvs[] >>
pop_assum mp_tac >> DEEP_INTRO_TAC some_intro >> rw[] >>
pop_assum $ qspec_then `n` assume_tac >>
Cases_on `step_n env n (Dstep dst deva dcs)` >> gvs[is_halt_def] >>
qspecl_then [`n`,`dst`,`deva`,`dcs`,`(st,devb,dcs)`,`env`]
assume_tac dstep_result_rel_n >>
gvs[dstep_result_rel_cases, is_Dffi_def] >>
gvs[is_halt_cml_def, dget_ffi_def]
)
>- (
simp[step_until_halt_def] >>
DEEP_INTRO_TAC some_intro >> rw[] >>
first_x_assum $ qspec_then `x` assume_tac >> gvs[is_halt_cml_def] >>
qspecl_then [`x`,`dst`,`deva`,`dcs`,`(st,devb,dcs)`,`env`]
assume_tac dstep_result_rel_n' >>
gvs[dstep_result_rel_cases, dget_ffi_def, is_halt_def]
)
QED
(******************** trace_prefix ********************)
Theorem dstep_not_SharedMem:
∀benv st decl c st' ffiname ws1 ws2 n env' ec locs p c'.
dstep benv st decl c = Dffi st' (ffiname,ws1,ws2,n,env',ec) locs p c' ==>
ffiname <> SharedMem mop
Proof
recInduct dstep_ind >>
rw[dstep_def] >>
gvs[DefnBase.one_line_ify NONE dcontinue_def,AllCaseEqs()] >>
gvs[DefnBase.one_line_ify NONE estep_def,AllCaseEqs(),
push_def,return_def] >>
gvs[DefnBase.one_line_ify NONE application_def,AllCaseEqs(),
return_def,push_def] >>
gvs[DefnBase.one_line_ify NONE continue_def,AllCaseEqs(),
return_def,push_def,
DefnBase.one_line_ify NONE application_def] >>
gvs[DefnBase.one_line_ify NONE exn_continue_def,AllCaseEqs(),
return_def,push_def]
QED
(* use FFI instead of SharedMem *)
Theorem do_app_not_SharedMem:
semanticPrimitives$do_app s op vs ≠ SOME (v, Rerr (Rabort (Rffi_error (Final_event (SharedMem
s') conf ws outcome))))
Proof
rpt strip_tac >>
gvs[DefnBase.one_line_ify NONE semanticPrimitivesTheory.do_app_def,
AllCaseEqs(),call_FFI_def] >>
rw[] >>
pairarg_tac >> fs[]
QED
Theorem application_not_SharedMem:
smallStep$application op env (refs,ffi) fp_state vs vs' ≠
Eabort (fp,Rffi_error (Final_event (SharedMem s') conf ws outcome))
Proof
rpt strip_tac >>
gvs[smallStepTheory.application_def,AllCaseEqs(),SF smallstep_ss,
do_app_not_SharedMem] >>
gvs[semanticPrimitivesTheory.do_fprw_def,AllCaseEqs()]
QED
Theorem decl_step_not_SharedMem:
decl_step env (st,devb,dcs) ≠ Dabort (fp,Rffi_error (Final_event (SharedMem
s') conf ws outcome))
Proof
strip_tac >>
gvs[decl_step_def,AllCaseEqs(),decl_continue_def] >>
gvs[DefnBase.one_line_ify NONE e_step_def,AllCaseEqs(),SF smallstep_ss] >>
gvs[application_not_SharedMem]
QED
Theorem trace_prefix_dec_Error:
dstate_rel dsta st ∧ deval_rel deva devb ⇒
((∃n. trace_prefix n (oracle, ffi_st)
(interp env (Dstep dsta deva dcs)) = (io, SOME Error)) ⇔
∃dst ffi' fp.
(decl_step_reln env)^*
(st with ffi := st.ffi with <| oracle := oracle; ffi_state := ffi_st |>,
devb, dcs) dst ∧
dget_ffi (Dstep dst) = SOME ffi' ∧
ffi'.io_events = st.ffi.io_events ++ io ∧
decl_step env dst = Dabort (fp, Rtype_error))
Proof
rw[] >> eq_tac >> rw[] >> rpt $ pop_assum mp_tac
>- (
map_every qid_spec_tac
[`dsta`,`deva`,`dcs`,`oracle`,`ffi_st`,`st`,`devb`,`env`,`io`,`n`] >>
Induct >> rw[trace_prefix_interp] >>
gvs[step_until_halt_def] >> every_case_tac >> gvs[]
>- (
qpat_x_assum `(some n. _ ) = _` mp_tac >>
DEEP_INTRO_TAC some_intro >> rw[] >>
drule is_halt_step_n_min >> strip_tac >> gvs[] >>
qpat_x_assum `step_n _ x _ = _` kall_tac >>
qpat_x_assum `_ ≤ x` kall_tac >>
`∃l. m = SUC l` by (Cases_on `m` >> gvs[step_n_def]) >> gvs[] >>
pop_assum $ qspec_then `l` assume_tac >> gvs[] >>
Cases_on `step_n env l (Dstep dsta deva dcs)` >> gvs[] >>
gvs[step_n_alt_def, is_halt_def] >>
rename1 `_ = Dstep dsta' deva' dcs'` >>
qmatch_goalsub_abbrev_tac `RTC _ (st',_)` >>
qspecl_then [`l`,`dsta`,`deva`,`dcs`,`(st',devb,dcs)`,`env`]
mp_tac dstep_result_rel_n >>
simp[dstep_result_rel_cases, is_Dffi_def] >> impl_tac
>- (unabbrev_all_tac >> gvs[dstate_rel_def]) >>
strip_tac >> gvs[dget_ffi_def] >>
rw[decl_step_reln_eq_step_n_cml, PULL_EXISTS] >> goal_assum drule >>
simp[dget_ffi_def] >> unabbrev_all_tac >>
gvs[state_component_equality, ffi_state_component_equality] >>
qspecl_then [`dsta'`,`deva'`,`dcs'`,`(st'',dev2,dcs')`,`env`]
mp_tac dstep_result_rel_single >>
simp[dstep_result_rel_cases, is_Dffi_def]
)
>- (pairarg_tac >> gvs[trace_prefix_def])
>- (
pairarg_tac >> gvs[] >>
rename1 `ExpVal env' _ cs locs pat` >>
rename1 `Dffi dst (s,ws1,ws2,lnum,env'',_) _ _ dcs'` >>
rename1 `_ conf ws = Oracle_return ffi_st' ws'` >>
qpat_x_assum `(some n. _ ) = _` mp_tac >>
DEEP_INTRO_TAC some_intro >> rw[] >>
drule is_halt_step_n_min >> strip_tac >> gvs[] >>
qpat_x_assum `step_n _ x _ = _` kall_tac >>
qpat_x_assum `_ ≤ x` kall_tac >>
`∃l. m = SUC l` by (Cases_on `m` >> gvs[step_n_def]) >> gvs[] >>
pop_assum $ qspec_then `l` assume_tac >> gvs[] >>
Cases_on `step_n env l (Dstep dsta deva dcs)` >> gvs[is_halt_def] >>
qmatch_goalsub_abbrev_tac `(st',_)` >>
qspecl_then [`l`,`dsta`,`deva`,`dcs`,`(st',devb,dcs)`,`env`]
mp_tac dstep_result_rel_n >>
simp[dstep_result_rel_cases, is_Dffi_def, dget_ffi_def] >>
impl_tac >- (unabbrev_all_tac >> gvs[dstate_rel_def]) >>
strip_tac >> gvs[dget_ffi_def] >>
gvs[step_n_alt_def] >>
rw[Once RTC_CASES_RTC_TWICE, PULL_EXISTS] >>
rw[Once RTC_CASES2] >> irule_at Any OR_INTRO_THM2 >>
simp[PULL_EXISTS, GSYM CONJ_ASSOC] >>
rw[decl_step_reln_eq_step_n_cml, PULL_EXISTS] >>
goal_assum drule >> rw[decl_step_reln_def] >>
Cases_on ‘s’>>fs[]>-
(
drule_at Any dstep_result_rel_single_FFI_strong >>
simp[dstep_result_rel_cases, PULL_EXISTS] >>
disch_then drule_all >> strip_tac >> gvs[dget_ffi_def] >>
unabbrev_all_tac >> gvs[ffi_state_component_equality] >>
qmatch_goalsub_abbrev_tac `Dstep (st2,ev,ll)` >>
last_x_assum $ drule_at $ Pos last >>
qpat_x_assum `deval_rel _ _` mp_tac >>
simp[deval_rel_cases, ctxt_rel_def, PULL_EXISTS] >>
simp[GSYM ctxt_rel_def, ctxt_frame_rel_cases] >> strip_tac >>
disch_then $ drule_at Any >>
disch_then $ qspec_then `st2` mp_tac >>
impl_tac >- (unabbrev_all_tac >> gvs[dstate_rel_def, dstep_to_Dffi]) >>