Add eachof function for iterating while reading from io

This saves boilerplate versus a while !eof(io); read(io, T) loop. The
function signature is patterned after the read(io, T) function
signature.

Prompted by #36132 but does not close #36132

I am open to better/clearer names for this function.

Author: non-Jedi

base/exports.jl

@@ -782,6 +782,7 @@ export
     close,
     countlines,
     eachline,
+    eachof,
     eof,
     fd,
     fdio,

base/io.jl

@@ -1003,6 +1003,46 @@ eltype(::Type{<:EachLine}) = String
 
 IteratorSize(::Type{<:EachLine}) = SizeUnknown()
 
+struct EachOfIO{T, IOT <: IO}
+    stream::IOT
+end
+
+"""
+    eachof(io::IO, T)
+
+Return an iterable object yielding [`read(io, T)`](@ref).
+
+See also: [`skipchars`](@ref), [`eachline`](@ref), [`readuntil`](@ref)
+
+!!! compat "Julia 1.6"
+    `eachof` requires Julia 1.6 or later.
+
+# Examples
+```jldoctest
+julia> open("my_file.txt", "w") do io
+           write(io, "JuliaLang is a GitHub organization.\\n It has many members.\\n");
+       end;
+
+julia> open("my_file.txt") do io
+           for c in eachof(io, Char)
+               c == '\\n' && break
+               print(c)
+           end
+       end
+JuliaLang is a GitHub organization.
+
+julia> rm("my_file.txt");
+```
+"""
+eachof(stream::IOT, T::Type) where IOT<:IO = EachOfIO{T,IOT}(stream)
+
+iterate(itr::EachOfIO{T}, state=nothing) where T =
+    eof(itr.stream) ? nothing : (read(itr.stream, T), nothing)
+
+eltype(::Type{EachOfIO{T}}) where T = T
+
+IteratorSize(::Type{<:EachOfIO}) = SizeUnknown()
+
 # IOStream Marking
 # Note that these functions expect that io.mark exists for
 # the concrete IO type. This may not be true for IO types

doc/src/base/io-network.md

@@ -19,6 +19,7 @@ Base.read!
 Base.readbytes!
 Base.unsafe_read
 Base.unsafe_write
+Base.eachof
 Base.peek
 Base.position
 Base.seek

test/read.jl

@@ -300,6 +300,12 @@ for (name, f) in l
 
         cleanup()
 
+        verbose && println("$name eachof...")
+        @test collect(eachof(io(), Char)) == Vector{Char}(text)
+        @test collect(eachof(io(), UInt8)) == Vector{UInt8}(text)
+
+        cleanup()
+
         verbose && println("$name countlines...")
         @test countlines(io()) == countlines(IOBuffer(text))