allow specifying multiple modules

Author: rfourquet

base/reflection.jl

@@ -866,14 +866,19 @@ Return the method table for `f`.
 
 If `types` is specified, return an array of methods whose types match.
 If `module` is specified, return an array of methods defined in this module.
+A list of modules can also be specified as an array or tuple.
 """
-function methods(@nospecialize(f), @nospecialize(t), mod::Union{Module,Nothing}=nothing)
+function methods(@nospecialize(f), @nospecialize(t),
+                 @nospecialize(mod::Union{Module,AbstractArray{Module},Tuple{Vararg{Module}}}=()))
+    if mod isa Module
+        mod = (mod,)
+    end
     if isa(f, Core.Builtin)
         throw(ArgumentError("argument is not a generic function"))
     end
     t = to_tuple_type(t)
     world = typemax(UInt)
-    MethodList(Method[m[3] for m in _methods(f, t, -1, world) if mod === nothing || m[3].module == mod],
+    MethodList(Method[m[3] for m in _methods(f, t, -1, world) if isempty(mod) || m[3].module in mod],
                typeof(f).name.mt)
 end
 
@@ -888,7 +893,8 @@ function methods_including_ambiguous(@nospecialize(f), @nospecialize(t))
     return MethodList(Method[m[3] for m in ms], typeof(f).name.mt)
 end
 
-function methods(@nospecialize(f), mod::Union{Module,Nothing}=nothing)
+function methods(@nospecialize(f),
+                 @nospecialize(mod::Union{Module,AbstractArray{Module},Tuple{Vararg{Module}}}=()))
     # return all matches
     return methods(f, Tuple{Vararg{Any}}, mod)
 end

test/reflection.jl

@@ -893,3 +893,30 @@ end
 @test nameof(:) === :Colon
 @test nameof(Core.Intrinsics.mul_int) === :mul_int
 @test nameof(Core.Intrinsics.arraylen) === :arraylen
+
+module TestMod33403
+f(x) = 1
+f(x::Int) = 2
+
+module Sub
+import ..TestMod33403: f
+f(x::Char) = 3
+end
+end
+
+@testset "methods with module" begin
+    using .TestMod33403: f
+    @test length(methods(f)) == 3
+    @test length(methods(f, (Int,))) == 1
+
+    @test length(methods(f, TestMod33403)) == 2
+    @test length(methods(f, (TestMod33403,))) == 2
+    @test length(methods(f, [TestMod33403])) == 2
+    @test length(methods(f, (Int,), TestMod33403)) == 1
+    @test length(methods(f, (Int,), (TestMod33403,))) == 1
+
+    @test length(methods(f, TestMod33403.Sub)) == 1
+    @test length(methods(f, (TestMod33403.Sub,))) == 1
+    @test length(methods(f, (Char,), TestMod33403.Sub)) == 1
+    @test length(methods(f, (Int,), TestMod33403.Sub)) == 0
+end