stdlib_experimental_stats_mean.fypp

#:include "common.fypp"

#:set RANKS = range(1, MAXRANK + 1)


submodule (stdlib_experimental_stats) stdlib_experimental_stats_mean

  use stdlib_experimental_error, only: error_stop
  implicit none

contains

  #:for k1, t1 in REAL_KINDS_TYPES
    #:for rank in RANKS
      module function mean_${rank}$_all_${k1}$_${k1}$(x) result(res)
        ${t1}$, intent(in) :: x${ranksuffix(rank)}$
        ${t1}$ :: res

        res = sum(x) / real(size(x, kind = int64), ${k1}$)

      end function mean_${rank}$_all_${k1}$_${k1}$
    #:endfor
  #:endfor


  #:for k1, t1 in INT_KINDS_TYPES
    #:for rank in RANKS
      module function mean_${rank}$_all_${k1}$_dp(x) result(res)
        ${t1}$, intent(in) :: x${ranksuffix(rank)}$
        real(dp) :: res

        res = sum(real(x, dp)) / real(size(x, kind = int64), dp)

      end function mean_${rank}$_all_${k1}$_dp
    #:endfor
  #:endfor


  #:for k1, t1 in REAL_KINDS_TYPES
    #:for rank in RANKS
      module function mean_${rank}$_${k1}$_${k1}$(x, dim) result(res)
        ${t1}$, intent(in) :: x${ranksuffix(rank)}$
        integer, intent(in) :: dim
        ${t1}$ :: res${reduced_shape('x', rank, 'dim')}$

        if (dim >= 1 .and. dim <= ${rank}$) then
          res = sum(x, dim) / real(size(x, dim), ${k1}$)
        else
          call error_stop("ERROR (mean): wrong dimension")
        end if

      end function mean_${rank}$_${k1}$_${k1}$
    #:endfor
  #:endfor


  #:for k1, t1 in INT_KINDS_TYPES
    #:for rank in RANKS
      module function mean_${rank}$_${k1}$_dp(x, dim) result(res)
        ${t1}$, intent(in) :: x${ranksuffix(rank)}$
        integer, intent(in) :: dim
        real(dp) :: res${reduced_shape('x', rank, 'dim')}$

        if (dim >= 1 .and. dim <= ${rank}$) then
          res = sum(x, dim) / real(size(x, dim), dp)
        else
          call error_stop("ERROR (mean): wrong dimension")
        end if

      end function mean_${rank}$_${k1}$_dp
    #:endfor
  #:endfor

end submodule