101-noise-2d.glsl

#ifdef GL_ES
precision mediump float;
#endif

uniform float u_time;
uniform vec2 u_resolution;

uniform vec2 u_mouse;


// 2D Random
float random (in vec2 st) {
    return fract(sin(dot(st.xy,
                         vec2(12.9898,78.233)))
                 * 43758.5453123);
}

// 2D Noise based on Morgan McGuire @morgan3d
// https://www.shadertoy.com/view/4dS3Wd
float noise (in vec2 st) {
    vec2 i = floor(st);
    vec2 f = fract(st);

    // Four corners in 2D of a tile
    float a = random(i);
    float b = random(i + vec2(1.0, 0.0));
    float c = random(i + vec2(0.0, 1.0));
    float d = random(i + vec2(1.0, 1.0));

    // Smooth Interpolation

    // Cubic Hermine Curve.  Same as SmoothStep()
    vec2 u = f*f*(3.0-2.0*f);
    // u = smoothstep(0.,1.,f);

    // Mix 4 coorners percentages
    return mix(a, b, u.x) +
            (c - a)* u.y * (1.0 - u.x) +
            (d - b) * u.x * u.y;
}

void main(){
    vec2 st = gl_FragCoord.xy/u_resolution.xy;

    // Scale the coordinate system to see
    // some noise in action
    float scale = 4.0;
    vec2 pos = vec2(st*scale);

    // Use the noise function
    float n = noise(pos);

    // Exercises:
    // scale the noise using the mouse
    // hint: you have to plug the u_mouse uniform into the scale variable

    // try to draw a rectangle modified by the noise

    // Have a look at the gradient noise. Try to compare it with the first noise
    // Make a variation of this sketch https://thebookofshaders.com/edit.php#11/wood.frag
    gl_FragColor = vec4(vec3(n), 1.0);
}