Replace wrapping with meck with a custom solution. (#1)

A meck-based solution was a good PoC, but ultimately not production-grade due to slowdowns introduced with piping all of the compilation through a single process and various overheads related to keeping track of mock expectations.

Author: kzemek

README.md

@@ -15,6 +15,27 @@ This often results in repetitive code patterns such as `ctx = %{variable: variab
 I believe that introducing a shorthand form of object creation to Elixir enhances the language's ergonomics and is a natural extension of its existing map literals syntax.
 This feature will be immediately familiar to JavaScript and Rust developers, and similar shorthands are present in other languages such as Go.
 
+## Installation
+
+The package can be installed by adding `es6_maps` to your list of dependencies and compilers in `mix.exs`:
+
+```elixir
+def project do
+  [
+    app: :testme,
+    version: "0.1.0",
+    compilers: [:es6_maps | Mix.compilers()],
+    deps: deps()
+  ]
+end
+
+def deps do
+  [
+    {:es6_maps, "~> 0.1.0", runtime: false}
+  ]
+end
+```
+
 ## Usage
 
 ### Creating maps
@@ -69,31 +90,10 @@ iex> hello
 
 ## How does it work?
 
-`es6_maps` uses [`meck`](https://github.com/eproxus/meck) to replace the implementation of Elixir compiler's `elixir_map` module.
-The module's `expand_map/4` function is then replaced to expand map keys `%{k}` as if they were `%{k: k}`.
+`es6_maps` replaces in runtime the Elixir compiler's `elixir_map` module.
+The module's `expand_map/4` function is wrapped with a function that replaces map keys `%{k}` as if they were `%{k: k}`.
 After `es6_maps` runs as one of the Mix compilers, the Elixir compiler will use the replaced functions to compile the rest of the code.
 
 > [!IMPORTANT]
 > By the nature of this solution it's tightly coupled to the internal Elixir implementation.
 > The current version of `es6_maps` should work for Elixir 1.15, 1.16 and the upcoming 1.17 version, but may break in the future.
-
-## Installation
-
-The package can be installed by adding `es6_maps` to your list of dependencies and compilers in `mix.exs`:
-
-```elixir
-def project do
-  [
-    app: :testme,
-    version: "0.1.0",
-    compilers: [:es6_maps | Mix.compilers()],
-    deps: deps()
-  ]
-end
-
-def deps do
-  [
-    {:es6_maps, "~> 0.1.0", runtime: false}
-  ]
-end
-```

lib/mix/tasks/compile.es6_map.ex

@@ -0,0 +1,64 @@
+defmodule Mix.Tasks.Compile.Es6Maps do
+  @moduledoc false
+
+  use Mix.Task.Compiler
+
+  def run(_args) do
+    {:elixir_map, elixir_map_bytecode, elixir_map_filename} = :code.get_object_code(:elixir_map)
+    elixir_map_forms = abstract_code(elixir_map_bytecode)
+    compile_opts = compile_opts(elixir_map_bytecode)
+    injected_forms = injected_forms()
+
+    {forms_start, [expand_map_forms | forms_end]} =
+      Enum.split_while(elixir_map_forms, &(not function?(&1, expand_map: 4)))
+
+    expand_map_orig_forms = rename_function(expand_map_forms, :es6_maps_expand_map_orig)
+    forms = Enum.concat([forms_start, injected_forms, [expand_map_orig_forms], forms_end])
+
+    {:ok, :elixir_map, binary, _warnings} =
+      :compile.forms(forms, [:return_errors, :return_warnings | compile_opts])
+
+    {:module, :elixir_map} = :code.load_binary(:elixir_map, elixir_map_filename, binary)
+
+    :ok
+  end
+
+  defp function?({:function, _, name, arity, _}, names), do: {name, arity} in names
+  defp function?(_form, _names), do: false
+
+  defp rename_function({:function, meta, _name, arity, clauses}, new_name),
+    do: {:function, meta, new_name, arity, clauses}
+
+  defp abstract_code(bytecode) do
+    {:ok, {_, abstract_code: abstract_code}} = :beam_lib.chunks(bytecode, [:abstract_code])
+    {:raw_abstract_v1, abstract} = abstract_code
+    abstract
+  end
+
+  defp compile_opts(bytecode) do
+    {:ok, {_, compile_info: info}} = :beam_lib.chunks(bytecode, [:compile_info])
+    Keyword.fetch!(info, :options)
+  end
+
+  defp injected_forms do
+    {:module, _, bytecode, _} =
+      defmodule Es6Map.InjectedCode do
+        def expand_map(meta, args, s, e),
+          do: es6_maps_expand_map_orig(meta, expand_atom_keys(args), s, e)
+
+        defp expand_atom_keys(args) do
+          Enum.map(args, fn
+            {:|, meta, [map, inner_args]} -> {:|, meta, [map, expand_atom_keys(inner_args)]}
+            {k, _meta, ctx} = v when is_atom(ctx) -> {k, v}
+            other -> other
+          end)
+        end
+
+        defp es6_maps_expand_map_orig(_meta, _args, _s, _e), do: nil
+      end
+
+    bytecode
+    |> abstract_code()
+    |> Enum.filter(&function?(&1, expand_map: 4, expand_atom_keys: 1))
+  end
+end

lib/mix/tasks/compile/es6_map.ex

@@ -25,7 +25,6 @@ defmodule Es6Maps.MixProject do
 
   defp deps do
     [
-      {:meck, "~> 0.9"},
       {:ex_doc, "~> 0.31", only: :dev, runtime: false}
     ]
   end

mix.exs

@@ -4,6 +4,5 @@
   "makeup": {:hex, :makeup, "1.1.1", "fa0bc768698053b2b3869fa8a62616501ff9d11a562f3ce39580d60860c3a55e", [:mix], [{:nimble_parsec, "~> 1.2.2 or ~> 1.3", [hex: :nimble_parsec, repo: "hexpm", optional: false]}], "hexpm", "5dc62fbdd0de44de194898b6710692490be74baa02d9d108bc29f007783b0b48"},
   "makeup_elixir": {:hex, :makeup_elixir, "0.16.2", "627e84b8e8bf22e60a2579dad15067c755531fea049ae26ef1020cad58fe9578", [:mix], [{:makeup, "~> 1.0", [hex: :makeup, repo: "hexpm", optional: false]}, {:nimble_parsec, "~> 1.2.3 or ~> 1.3", [hex: :nimble_parsec, repo: "hexpm", optional: false]}], "hexpm", "41193978704763f6bbe6cc2758b84909e62984c7752b3784bd3c218bb341706b"},
   "makeup_erlang": {:hex, :makeup_erlang, "0.1.5", "e0ff5a7c708dda34311f7522a8758e23bfcd7d8d8068dc312b5eb41c6fd76eba", [:mix], [{:makeup, "~> 1.0", [hex: :makeup, repo: "hexpm", optional: false]}], "hexpm", "94d2e986428585a21516d7d7149781480013c56e30c6a233534bedf38867a59a"},
-  "meck": {:hex, :meck, "0.9.2", "85ccbab053f1db86c7ca240e9fc718170ee5bda03810a6292b5306bf31bae5f5", [:rebar3], [], "hexpm", "81344f561357dc40a8344afa53767c32669153355b626ea9fcbc8da6b3045826"},
   "nimble_parsec": {:hex, :nimble_parsec, "1.4.0", "51f9b613ea62cfa97b25ccc2c1b4216e81df970acd8e16e8d1bdc58fef21370d", [:mix], [], "hexpm", "9c565862810fb383e9838c1dd2d7d2c437b3d13b267414ba6af33e50d2d1cf28"},
 }

mix.lock

@@ -1,3 +0,0 @@
-%{
-  "meck": {:hex, :meck, "0.9.2", "85ccbab053f1db86c7ca240e9fc718170ee5bda03810a6292b5306bf31bae5f5", [:rebar3], [], "hexpm", "81344f561357dc40a8344afa53767c32669153355b626ea9fcbc8da6b3045826"},
-}