FRESSEN.bc

1000 A=100:GOTO20:REM RAUB-BUETETIERE-ZYKLUS
1010 HB=HO:VB=VE:UW=1-1/HG:P1=3.14159:MT=0:TM=0:IV=255
1020 IT=0:RA=0:RB=0:RC=0:RD=0:PA=0:PB=0:PC=0:PD=0
1030 DIMCO$(8)
1040 FORI=0 TO8:READCO$(I):NEXTI
1050 GOSUB100:GOSUB9040:SR$="RAUB-BEUTETIERE-ZYKLUS"
1060 VE=2:HO=INT(HB/2-11)-3:GOSUB110:GOSUB150
1070 PRINT:PRINT:GOSUB9040
1080 RG=RA+RB:RK=RA-RB:PG=PA+PB:PK=PA-PB:PR=1
1090 FORVE=6 TO14
1100 HO=HB/2-5:GOSUB110:PRINTCO$(VE-6)
1110 NEXTVE
1120 PRINT:GOSUB9040
1130 VE=18:HO=0:GOSUB110
1140 PRINT"Waehle mittels der Cursortasten"
1150 PRINT"und schliesse mit Return ab !"
1160 PRINT:GOSUB9040
1170 VE=6:HO=HB/2-8:SR$=CO$(VE-6):GOSUB110:GOSUB150
1180 GOSUB200:IF((IN<28)OR(IN>31))AND(IN<>13)THEN1180
1190 IFIN=13 THEN1280
1200 SR$="   "+CO$(VE-6)+"   ":GOSUB110:PRINTSR$
1210 IF(IN=30)AND(VE=14)THENVE=5
1220 IFIN=30 THENVE=VE+1
1230 IF(IN=31)AND(VE=6)THENVE=15
1240 IFIN=31 THENVE=VE-1
1250 IFIN=28 THENVE=6
1260 IFIN=29 THENVE=14
1270 SR$=CO$(VE-6):GOSUB110:GOSUB150:GOTO1180
1280 IFVE=14 THEN GOSUB100:GOTO950
1290 IF(VE<8)OR(IV=0)OR(VE=13)THEN1330
1300 HO=INT(HB/2-17):VE=VB-2:GOSUB110
1310 SR$="Du hast noch nichts eingegeben!":GOSUB150
1320 GOSUB9110:GOTO1050
1330 ONVE-5 GOSUB2010,3010,4010,5010,6010,7010,8010,8510
1340 IF(IN=83)AND(VE<>VB)THEN GOSUB20000
1350 GOTO1050
2000 REM ERKLAERUNG
2010 SR$="BEUTE-RAUBTIER-ZYKLUS":GOSUB9010
2020 PRINT:PRINT:PRINT"Durch den Wissenschaftler Volterra"
2030 PRINT"wurde, angeregt durch den Biologen d'Ancona,"
2040 PRINT"im Jahre 1931 ein wissenschaftliches Modell"
2050 PRINT"der Wechselwirkung zwischen Beute- und"
2060 PRINT"Raubtieren formuliert."
2070 PRINT"Der Ausgangspunkt ist, dass die Zunahme"
2080 PRINT"des Anteiles an Raubtieren dafuer sorgt, dass"
2090 PRINT"auch mehr Beutetiere gefangen werden."
2100 PRINT"Dadurch nehmen aber die Beutetiere"
2110 PRINT"anteilig ab, sodass es weniger Futter"
2120 PRINT"fuer die Raubtiere gibt und sie dadurch"
2130 PRINT"anteilig abnehmen. Hierdurch nehmen"
2140 PRINT"die Raubtiere wieder anteilig zu, es gibt"
2150 PRINT"wieder genuegend Futter wodurch der"
2160 PRINT"Anteil Raubtiere wieder zunimmt, usw.":GOSUB9110
2170 GOSUB100:PRINT"Natuerlich wurden viele Einwaende gegen"
2180 PRINT"dieses Modell vorgebracht. So soll es vielfach"
2190 PRINT"sein,dass Raubtiere von mehr als einer"
2200 PRINT"Sorte Beutetieren leben. Weiter soll"
2210 PRINT"das Klima Einfluss haben koennen."
2220 GOSUB9110:GOSUB100
2230 PRINT"Als aber keine Rechnung mit diesen"
2240 PRINT"Faktoren geholfen hat, konnte dieser"
2250 PRINT"Zyklus beruhigt wissenschaftlich durch"
2260 PRINT"eine Funktion fuer den Anteil an"
2270 PRINT"Beute- und Raubtieren aufgestellt werden."
2280 PRINT"Diese Funktion lautet wie folgt:"
2290 PRINT"     P(t)=A+B*sin C(t+D)."
2300 PRINT"Dabei stellt 't' die Zeit dar.":GOSUB9110
2310 GOSUB100:PRINT"Mit diesem Programm kannst du selbst"
2320 PRINT"die Funktion zusammenstellen und dann"
2330 PRINT"grafisch darstellen."
2340 PRINT:PRINT"Du kannst ein Screendumpprogramm"
2350 PRINT"platzieren ab Zeilennummer 20000."
2360 PRINT"Wenn du 'S' drueckst wenn eine Grafik"
2370 PRINT"gezeichnet ist, erhaeltst du"
2380 PRINT"einen Ausdruck auf Papier."
2390 PRINT:PRINT"Es ist ein Demo dabei, so dass"
2400 PRINT"du sehen kannst, was gemeint ist.":PRINT
2410 PRINT"VIEL SPASS MIT DIESEM PROGRAMM !"
2420 GOSUB9110:RETURN
3000 REM EINGABEN
3010 SR$="EINGABE":GOSUB9010:IV=0
3020 PRINT:PRINT"Die Raub-Beutetierfunktion hat die"
3030 PRINT"Form: A+B*sin C(t+D), (t ist die Zeit)."
3040 PRINT:PRINT"Gebe die Parameter fuer die Raub-"
3050 PRINT"tierfunktion ein."
3060 GOSUB3130:RA=PA:RB=PB:RC=PC:RD=PD
3070 PRINT:PRINT"Gebe die Parameter fuer die Beute-"
3080 PRINT"tierfunktion ein.":GOSUB3130
3090 PRINT:PRINT"Eingabe der minimalen Zeit: ";:INPUTMT
3100 PRINT"Eingabe der maximalenZeit: ";:INPUTTM
3110 PRINT"Eingabe des Zeitintervalls: ";:INPUTIT
3120 RETURN
3130 PRINT:PRINT"A=";:INPUTPA
3140 PRINT"B=";:INPUTPB
3150 PRINT"C=";:INPUTPC$:PC=VAL(PC$)
3160 FORI=1 TOLEN(PC$):H$=MID$(PC$,I,2)
3170 IF(H$="PI")OR(H$="pi")THENPC=PC*P1
3180 NEXTI
3190 PRINT"D=";:INPUTPD:RETURN
4000 REM ABAENDERN
4010 SR$="ABAENDERN":GOSUB9010
4020 PRINT:PRINT"Was wilst du aendern:"
4030 PRINT:PRINT"Von den Raubtierfunktionen:":PRINT
4040 PRINT" 1. A (nun";RA;")":PRINT" 2. B (nun";RB;")"
4050 PRINT" 3. C (nun";RC;")":PRINT" 4. D (nun";RD;")"
4060 PRINT:PRINT"Von den Beutetierfunktionen:":PRINT
4070 PRINT" 5. A (nun";PA;")":PRINT" 6. B (nun";PB;")"
4080 PRINT" 7. C (nun";PC;")":PRINT" 8. D (nun";PD;")"
4090 PRINT:PRINT" 9. Die minimale Zeit (nun";MT;")"
4100 PRINT"10. Die maximale Zeit (nun";TM;")"
4110 PRINT"11. Das Zeidintervall (nun";IT;")"
4120 PRINT:PRINT"Treffe deine Wahl: ";:INPUTKE
4130 IFKE=0 THENRETURN
4140 IF(KE<1)OR(KE>11)THEN4120
4150 IFKE>8 THEN4170
4160 ONKE GOTO4180,4210,4240,4300,4180,4210,4240,4300
4170 ONKE-8 GOTO4330,4340,4350
4180 PRINT"Gib das neue A:";:INPUTH
4190 IFKE=1 THENRA=H:GOTO4360
4200 PA=H:GOTO4360
4210 PRINT"Gib das neue B:";:INPUTH
4220 IFKE=2 THENRB=H:GOTO4360
4230 PB=H:GOTO4360
4240 PRINT"Gib das neue C:";:INPUTH$
4250 H=VAL(H$):FORI=1 TOLEN(H$):PC$=MID$(H$,I,2)
4260 IF(PC$="PI")OR(PC$="pi")THENH=H*P1
4270 NEXTI
4280 IFKE=3 THENRC=H:GOTO4360
4290 PC=H:GOTO4360
4300 PRINT"Gib das neue D:";:INPUTH
4310 IFKE=4 THENRD=H:GOTO4360
4320 PD=H:GOTO4360
4330 PRINT"Gib die neue minimale t:";:INPUTMT:GOTO4360
4340 PRINT"Gib die neue maximale t:";:INPUTTM:GOTO4360
4350 PRINT"Gib das neue Zeitintervall";:INPUTIT
4360 HO=0:VE=VB:GOSUB110
4370 PRINT"Wilst du noch mehr aendern (J/N)";:GOSUB210
4380 IFIN=74 THEN4010
4390 RETURN
5000 REM TAFEL
5010 SR$="TAFEL":GOSUB9010:IFPR=2 THEN5130
5020 PRINT:PRINT"Soll die Ausgabe auf den Drucker (J/N)";
5030 GOSUB210:IFIN=78 THENPR=0:GOTO5130
5040 SR$="Die Raubtierfunktion ist: ":GOSUB350
5050 H1=RA:H2=RB:H3=RC:H4=RD:GOSUB5080
5060 SR$="Die Beutetierfunktion ist: ":GOSUB350
5070 H1=PA:H2=PB:H3=PC:H4=PD:GOSUB5080:GOTO5130
5080 SR=H1:GOSUB300:H$=SR$+"+"
5090 SR=H2:GOSUB300:H$=H$+SR$+"*sin ":SR=H3:GOSUB300
5100 H$=H$+SR$+"(t":IFH4>=0 THENH$=H$+"+"
5110 SR=H4:GOSUB300:H$=H$+SR$+")":SR$=H$
5120 GOSUB350:GOSUB360:RETURN
5130 HO=0:VE=2:GOSUB110
5140 PR$="  Zeit    Beutetier   Raubtier    ":SR$=PR$
5150 IFPR=1 THEN GOSUB360:GOSUB350:GOSUB360
5160 PRINTSR$:SP$="   ----------------------------"
5170 SR$=SP$:IFPR=1 THEN GOSUB350:GOSUB360
5180 PRINTSR$:RT=2
5190 FORT=MT TOTM STEPIT
5200 SR=T:CT=4:CN=1:GOSUB310:H$="       "+SR$+"     "
5210 GOSUB9140:CN=0:CT=6
5220 RT=RT+1:IF(RT<VB-1)OR(PR=1)THEN5240
5230 GOSUB9110:GOSUB100:PRINTPR$:PRINTSP$:RT=1
5240 SR=X:GOSUB310:H$=H$+SR$:SR=Y:GOSUB310
5250 SR$=H$+"     "+SR$:PRINTSR$
5260 IFPR=1 THEN GOSUB350:GOSUB360
5270 NEXTT
5280 GOSUB9110:RETURN
6000 REM PARAMETER
6010 GOSUB600:CN=0
6020 HO=.01:VE=0:GOSUB620:VE=.91:GOSUB630
6030 HO=UW:GOSUB630
6040 FORVE=0 TO.91 STEP.182
6050 HO=0:GOSUB620:HO=.02:GOSUB630
6060 NEXTVE
6070 FORHO=UW TO.01 STEP-.1
6080 VE=.903:GOSUB620:VE=.917:GOSUB630
6090 NEXTHO
6100 SR$="0":VE=.94:HO=0:GOSUB650
6110 SR=RG+INT(.1*RG):GOSUB300:HO=.02:VE=0:GOSUB650
6120 SR=PG+INT(.1*PG):GOSUB300:HO=1-LEN(SR$)/32
6130 VE=.86:GOSUB650:FORT=MT TOTM STEPIT
6140 GOSUB9140:H=X/(PG+.1*PG):V=1-Y/(RG+.1*RG)
6150 IFT=MT THENHO=H:VE=V:GOSUB620:X1=H:Y1=V:GOTO6170
6160 HO=X1:VE=Y1:GOSUB620:HO=H:VE=V:GOSUB630:X1=H:Y1=V
6170 NEXTT
6180 SR$="Beutetier":HO=.75:VE=.94:GOSUB650
6190 FORT=1 TO8
6200 SR$=MID$("Raubtier",T,1):VE=T/25+.05:HO=.03
6210 GOSUB650:NEXTT
6220 GOSUB9180:RETURN
7000 REM GRAFIK
7010 GOSUB600:CN=0
7020 VE=0:HO=.01:GOSUB620:VE=.91:GOSUB630
7030 HO=.989:GOSUB630:VE=0:GOSUB630
7040 FORVE=0 TO.91 STEP.185
7050 HO=0:GOSUB620:HO=.02:GOSUB630
7060 HO=.98:GOSUB620:HO=UW:GOSUB630
7070 NEXTVE
7080 FORHO=.01 TO1 STEP1/((TM-MT)/IT)
7090 VE=.903:GOSUB620:VE=.917:GOSUB630
7100 NEXTHO
7110 SR=MT:GOSUB300:HO=0:VE=.94:GOSUB650
7120 SR=TM:GOSUB300:HO=1-LEN(SR$)/32:GOSUB650
7130 SR=PG:GOSUB300:HO=.02:VE=0.02:GOSUB650
7140 VE=.87:SR=PK:GOSUB300:GOSUB650
7150 SR=RG:GOSUB300:VE=.02:HO=1-LEN(SR$)/32:GOSUB650
7160 SR=RK:GOSUB300:VE=.87:HO=1-LEN(SR$)/32:GOSUB650
7170 FORT=MT TOTM STEPIT
7180 H=(T-MT)*TM/(TM-MT)/(TM/.98)+.01
7190 GOSUB9140
7200 V=.91-(X-PK)*PG/(PG-PK)/(PG/.91)
7210 IFT=MT THENVE=V:HO=H:GOSUB620:Y1=V:X1=H:GOTO7230
7220 HO=X1:VE=Y1:GOSUB620:HO=H:VE=V:GOSUB630:Y1=V
7230 IFT=MT+10*IT THENSR$="B":GOSUB650
7240 V=.91-(Y-RK)*RG/(RG-RK)/(RG/.91)
7250 IFT=MT THENVE=V:GOSUB620:Y2=V:GOTO7270
7260 HO=X1:VE=Y2:GOSUB620:HO=H:VE=V:GOSUB630:Y2=V:X1=H
7270 IFT=MT+7*IT THENSR$="R":GOSUB650
7280 NEXTT
7290 GOSUB9180:RETURN
8000 REM KOMBINATION
8010 GOSUB600:CN=0
8020 HO=.5:VE=0:GOSUB620:VE=UW:GOSUB630
8030 HO=UW:VE=.5:GOSUB620:HO=0:GOSUB630
8040 FORVE=0 TO1 STEP.0999
8050 HO=.495:GOSUB620:HO=.507:GOSUB630:NEXTVE
8060 FORHO=0 TO1 STEP.0999
8070 VE=.495:GOSUB620:VE=.505:GOSUB630:NEXTHO
8080 SR=RG:GOSUB300:HO=.5-LEN(SR$)/32:VE=0:GOSUB650
8090 SR=RK:GOSUB300:HO=.5-LEN(SR$)/32:VE=.45:GOSUB650
8100 SR=PK:GOSUB300:HO=.51:GOSUB650
8110 SR=PG:GOSUB300:HO=1-LEN(SR$)/32:GOSUB650
8120 SR=MT:GOSUB300:HO=0:VE=.52:GOSUB650
8130 HO=.5+LEN(SR$)/32:GOSUB650
8140 SR=TM:GOSUB300:HO=.5-LEN(SR$)/32:GOSUB650
8150 VE=.96:HO=.5+(LEN(SR$)-1)/32:GOSUB650
8160 SR$="Zeit":HO=.2:VE=.52:GOSUB650
8170 FORI=1 TO4:SR$=MID$("Zeit",I,1)
8180 VE=I*.04+.6:HO=.46:GOSUB650:NEXTI
8190 SR$="Beute":HO=.7:VE=.52:GOSUB650
8200 FORI=1 TO4:SR$=MID$("Raub",I,1)
8210 VE=I*.04+.1:HO=.46:GOSUB650:NEXTI
8220 N=1:IP=INT(((TM-MT)/IT/4)):AP=0
8230 FORT=MT TOTM STEPIT
8240 GOSUB9140
8250 V=(T-MT)*TM/(TM-MT)/(TM/.485)+.51
8260 H=(X-PK)*PG/(PG-PK)/(PG/.485)+.51
8270 IFT=MT THENVE=V:HO=H:GOSUB620:X1=H:Y1=V:GOTO8290
8280 HO=X1:VE=Y1:GOSUB620:HO=H:VE=V:GOSUB630:X1=H:Y1=V
8290 H=(T-MT)*TM/(TM-MT)/(TM/.49)+.01
8300 V=.49-(Y-RK)*RG/(RG-RK)/(RG/.49)
8310 IFT=MT THENVE=V:HO=H:GOSUB620:X2=H:Y2=V:GOTO8330
8320 HO=X2:VE=Y2:GOSUB620:HO=H:VE=V:GOSUB630:X2=H:Y2=V
8330 H=(X-PK)*PG/(PG-PK)/(PG/.485)+.51
8340 V=.49-(Y-RK)*RG/(RG-RK)/(RG/.49)
8350 IFT=MT THENHO=H:VE=V:GOSUB620:X3=H:Y3=V:GOTO8390
8360 HO=X3:VE=Y3:GOSUB620:HO=H:VE=V:GOSUB630:X3=H:Y3=V
8370 AP=AP+1:IF(AP<IP*N)OR(N>3)THEN8390
8380 ONN GOSUB9210,9410,9610:N=N+1
8390 NEXTT
8400 GOSUB9180:RETURN
8500 REM DEMO
8510 RESTORE:FORI=1 TO9:READIN$:NEXTI
8520 READPA:READPB:READPC:READPD
8530 READRA:READRB:READRC:READRD
8540 READMT:READTM:READIT
8550 RG=RA+RB:RK=RA-RB:PG=PA+PB:PK=PA-PB:PR=2
8560 FORI=1 TO4:ONI GOSUB5010,6010,7010,8010
8570 NEXTI:IV=0:RETURN
9000 REM ZENTRIEREN, REVERS DRUCKEN
9010 GOSUB100:VE=0:HO=INT(HB/2-LEN(SR$)/2)-3
9020 GOSUB110:GOSUB150:PRINT:RETURN
9030 REM LINIEN ZIEHEN
9040 FORI=1 TOHB:PRINT"-";:NEXTI:RETURN
9100 REM TASTE
9110 VE=VB:HO=HB-7:GOSUB110:PRINT"<TASTE>";
9120 GOSUB210:RETURN
9130 REM BEUTETIEREFUNKTION
9140 X=PA+PB*SIN(PC*(T+PD))
9150 REM RAUBTIEREFUNKTION
9160 Y=RA+RB*SIN(RC*(T+RD)):RETURN
9170 REM TASTE HIERHER
9180 SV=15:SD=1:SP=70:GOSUB400:SP=90:GOSUB400
9190 GOSUB210:RETURN
9200 REM DREIECK (PUNKT NACH OBEN)
9210 F1=X1:F2=Y1:GOSUB9300
9220 F1=X2:F2=Y2:GOSUB9300
9230 F1=X3:F2=Y3:GOSUB9300
9240 GOSUB9810:RETURN
9300 HO=F1-.015:VE=F2+.01:GOSUB620:HO=HO+.03:GOSUB630
9310 HO=HO-.015:VE=VE-.03:GOSUB630:HO=HO-.015
9320 VE=VE+.03:GOSUB630:HO=HO+.03:GOSUB630:RETURN
9400 REM VIERKANT
9410 F1=X1:F2=Y1:GOSUB9500
9420 F1=X2:F2=Y2:GOSUB9500
9430 F1=X3:F2=Y3:GOSUB9500
9440 GOSUB9810:RETURN
9500 HO=F1-.01:VE=F2+.015:GOSUB620:HO=HO+.02
9510 GOSUB630:VE=VE-.03:GOSUB630:HO=HO-.02
9520 GOSUB630:VE=VE+.03:GOSUB630:RETURN
9600 REM DREIECK (PUNKT NACH UNTEN)
9610 F1=X1:F2=Y1:GOSUB9700
9620 F1=X2:F2=Y2:GOSUB9700
9630 F1=X3:F2=Y3:GOSUB9700
9640 GOSUB9810:RETURN
9700 HO=F1-.015:VE=F2-.015:GOSUB620:HO=HO+.03
9710 GOSUB630:HO=HO-.015:VE=VE+.03:GOSUB630
9720 HO=HO-.015:VE=VE-.03:GOSUB630:RETURN
9800 REM PUNKTLINIEN
9810 HO=X1:FORVE=Y1 TOY2 STEP-2/VG
9820 GOSUB620:NEXTVE
9830 VE=Y2:FORHO=X2 TOX3 STEP2/HG
9840 GOSUB620:NEXTHO
9850 RETURN
20000 RETURN
20010 REM ***********************************
20020 REM HIER KANNST DU EIN SCREENDUMPPROGRAMM
20030 REM EINBAUEN. WENN EIN GRAFIKPROGRAMM
20040 REM GEZEICHNET IST UND DU DRUECKST 'S' SPRINGT
20050 REM DAS PROGRAMM HIERHER.
20060 REM ***********************************
20070 RETURN
25000 DATA"Erklaerung","Eingaben","Aenderungen","Tafel"
25010 DATA"Parameter","Grafik","Combinationen"
25020 DATA"Demo","Ende"
25030 REM DATEN FUER DIE DEMO. DU KANNST DIESE DATEN
25040 REM NACH EIGENEN BDUERFNISSEN AENDERN.
25050 REM NACHFOLGEND STEHT HIER:
25060 REM A, B, C UND D VON DER BEUTETIERFUNKTION.
25070 REM A, B, C UND D VON DER RAUBTIERFUNKTION.
25080 REM MINIMALE ZEIT, MAXIMALE ZEIT, ZEITINTERVALL.
25090 DATA3400,2200,0.2618,-19
25100 DATA240,160,0.2618,-4
25110 DATA0,24,1
32000 REM *****************************
32010 REM DURCH RONALD VAN VUGT (PA3EAH)
32020 REM
32030 REM POSTBUS 160, 5580 AD, WAALRE
32040 REM
32050 REM        MAI, 1987, V1.2
32060 REM *****************************
32070 REM TROS-RADIO DD 870722
32100 REM
32110 REM #####################
32120 REM UEBERSETZT DURCH :
32130 REM BERND SCHNEIDER
32140 REM DR.-W.-KUELZ-STR. 55
32150 REM BRAND-ERBISDORF,9230
32160 REM AUF > MRB Z1013 <
32170 REM  +++ OSTERN 1990 +++
32180 REM #####################
32190 REM
32200 REM Erstausstrahlung: Deutschlandsender Kultur
32210 REM-spezial 901212