new runner: floaterm, try with :AsyncRun -mode=term -pos=floaterm ls -la

Author: skywind3000

autoload/asyncrun/runner/floaterm.vim

@@ -0,0 +1,67 @@
+"======================================================================
+"
+" floaterm.vim - 
+"
+" Created by skywind on 2021/12/15
+" Last Modified: 2021/12/15 06:47:18
+"
+"======================================================================
+
+" vim: set ts=4 sw=4 tw=78 noet :
+
+function! s:floaterm_close() abort
+	if &ft == 'floaterm' | return | endif
+	for b in tabpagebuflist()
+		if getbufvar(b, '&ft') == 'floaterm' &&
+					\ getbufvar(b, 'floaterm_jobexists') == v:false
+			execute b 'bwipeout!'
+			break
+		endif
+	endfor
+	autocmd! close-floaterm-runner
+endfunc
+
+
+"----------------------------------------------------------------------
+" floaterm
+"----------------------------------------------------------------------
+function! asyncrun#runner#floaterm#run(opts)
+	if exists(':FloatermNew') != 2
+		return asyncrun#utils#errmsg('require voldikss/vim-floaterm')
+	endif
+	if exists('*asyncrun#script_write') == 0
+		return asyncrun#utils#errmsg('require asyncrun 2.7.8 or above')
+	endif
+	let cmd = 'FloatermNew '
+	let cmd .= ' --wintype=float'
+	if has_key(a:opts, 'position') 
+		let cmd .= ' --position=' . fnameescape(a:opts.position)
+	endif
+	if has_key(a:opts, 'width')
+		let cmd .= ' --width=' . fnameescape(a:opts.width)
+	endif
+	if has_key(a:opts, 'height')
+		let cmd .= ' --height=' . fnameescape(a:opts.height)
+	endif
+	if has_key(a:opts, 'title')
+		let cmd .= ' --title=' . fnameescape(a:opts.title)
+	endif
+	let cmd .= ' --autoclose=0'
+	let cmd .= ' --silent=' . get(a:opts, 'silent', 0)
+	let cwd = (a:opts.cwd == '')? getcwd() : (a:opts.cwd)
+	let cmd .= ' --cwd=' . fnameescape(cwd)
+	" for precisely arguments passing and shell builtin commands
+	" a temporary file is introduced
+	let cmd .= ' ' . fnameescape(asyncrun#script_write(a:opts.cmd, 0))
+	exec cmd
+	if get(a:opts, 'focus', 1) == 0
+		stopinsert | noa wincmd p
+		augroup close-floaterm-runner
+			autocmd!
+			autocmd CursorMoved,InsertEnter * ++nested
+						\ call timer_start(100, { -> s:floaterm_close() })
+		augroup END
+	endif
+endfunc
+
+

autoload/asyncrun/runner/floaterm_reuse.vim

@@ -0,0 +1,27 @@
+"======================================================================
+"
+" floater_reuse.vim - 
+"
+" Created by skywind on 2021/12/15
+" Last Modified: 2021/12/15 06:48:57
+"
+"======================================================================
+
+" vim: set ts=4 sw=4 tw=78 noet :
+
+function! asyncrun#runner#floaterm_reuse#run(opts)
+	let curr_bufnr = floaterm#curr()
+	if has_key(a:opts, 'silent') && a:opts.silent == 1
+		FloatermHide!
+	endif
+	let cmd = 'cd ' . shellescape(getcwd())
+	call floaterm#terminal#send(curr_bufnr, [cmd])
+	call floaterm#terminal#send(curr_bufnr, [a:opts.cmd])
+	stopinsert
+	if &filetype == 'floaterm' && g:floaterm_autoinsert
+		call floaterm#util#startinsert()
+	endif
+	return 0
+endfunc
+
+

autoload/asyncrun/utils.vim

@@ -0,0 +1,32 @@
+"======================================================================
+"
+" utils.vim - 
+"
+" Created by skywind on 2021/12/15
+" Last Modified: 2021/12/15 06:33:42
+"
+"======================================================================
+
+" vim: set ts=4 sw=4 tw=78 noet :
+
+
+"----------------------------------------------------------------------
+" output msg
+"----------------------------------------------------------------------
+function! asyncrun#utils#errmsg(msg)
+	redraw
+	echohl ErrorMsg
+	echom 'ERROR: ' . a:msg
+	echohl NONE
+	return 0
+endfunc
+
+
+"----------------------------------------------------------------------
+" display require message
+"----------------------------------------------------------------------
+function! asyncrun#utils#require(what)
+	call asyncrun#utils#errmsg('require: ' . a:what . ' ')
+endfunc
+
+

plugin/runner_load.vim

@@ -0,0 +1,65 @@
+"======================================================================
+"
+" runner_load.vim - 
+"
+" Created by skywind on 2021/12/15
+" Last Modified: 2021/12/15 05:40:55
+"
+"======================================================================
+
+" vim: set ts=4 sw=4 tw=78 noet :
+
+
+"----------------------------------------------------------------------
+" internal
+"----------------------------------------------------------------------
+let g:asyncrun_event = get(g:, 'asyncrun_event', {})
+let g:asyncrun_runner = get(g:, 'asyncrun_runner', {})
+let s:script_time = {}
+
+
+"----------------------------------------------------------------------
+" find script 
+"----------------------------------------------------------------------
+function! s:find_script(name)
+	let test = 'autoload/asyncrun/runner/' . a:name . '.vim'
+	let fn = findfile(test, &rtp)
+	if fn == ''
+		return ''
+	endif
+	let fn = fnamemodify(fn, ':p')
+	let fn = substitute(fn, '\\', '/', 'g')
+	return fn
+endfunc
+
+
+"----------------------------------------------------------------------
+" load runner
+"----------------------------------------------------------------------
+function! s:load_runner(name)
+	let name = a:name
+	let load = s:find_script(name)
+	let test = 'asyncrun#runner#' . name . '#run'
+	if filereadable(load) && load != ''
+		let mtime = getftime(load)
+		let ltime = get(s:script_time, load, 0)
+		if mtime > ltime
+			exec 'source ' . fnameescape(load)
+			let s:script_time[load] = mtime
+		endif
+		if exists('*' . test)
+			let g:asyncrun_runner[name] = test
+		endif
+	endif
+endfunc
+
+
+"----------------------------------------------------------------------
+" init runner
+"----------------------------------------------------------------------
+function! g:asyncrun_event.runner(name)
+	call s:load_runner(a:name)
+endfunc
+
+
+