✨[Mob301]業深き想いV2を作成

Asset/data/asset/functions/mob/0301.karmic/_index.d.mcfunction

@@ -0,0 +1,54 @@
+#> asset:mob/0301.karmic/_index.d
+# @private
+
+#> tag
+# @within function asset:mob/0301.karmic/**
+    #declare tag 8D.AJ
+    #declare tag 8D.AJLink
+    #declare tag 8D.SkipSkillSelect
+    #
+    #declare tag 8D.Opening
+    #declare tag 8D.Fall
+    #declare tag 8D.SkillDash
+    #declare tag 8D.SkillSlash
+    #declare tag 8D.SkillGun
+    #declare tag 8D.SkillGunLoop
+    #declare tag 8D.SkillGunEnd
+    #declare tag 8D.SkillSwordCange
+    #declare tag 8D.SkillDash1
+    #declare tag 8D.SkillDash2
+    #declare tag 8D.SkillDash3
+    #declare tag 8D.SkillSword1
+    #declare tag 8D.SkillSword2
+    #declare tag 8D.SkillSword3
+    #
+    #declare tag TeleportCheck
+    #
+    #declare function animated_java:karmic/summon
+    #declare function animated_java:karmic/variants/girl/apply
+    #declare function animated_java:karmic/animations/wait/play
+    #declare function animated_java:karmic/animations/wait/stop
+    #declare function animated_java:karmic/animations/summon/play
+    #declare function animated_java:karmic/animations/run_start/play
+    #declare function animated_java:karmic/animations/run_start/stop
+    #declare function animated_java:karmic/animations/run_loop/play
+    #declare function animated_java:karmic/animations/run_loop/stop
+    #declare function animated_java:karmic/animations/run_end_slash/play
+    #declare function animated_java:karmic/animations/run_end_sliding/play
+    #declare function animated_java:karmic/animations/attack/play
+    #declare function animated_java:karmic/animations/guntpstart/play
+    #declare function animated_java:karmic/animations/guntp/play
+    #declare function animated_java:karmic/animations/guntpend/play
+    #declare function animated_java:karmic/animations/sword_wait/play
+    #declare function animated_java:karmic/animations/sword_wait/stop
+    #declare function animated_java:karmic/animations/sword_change/play
+    #declare function animated_java:karmic/animations/sword_attack1/play
+    #declare function animated_java:karmic/animations/sword_run/play
+    #declare function animated_java:karmic/animations/sword_run_slash/play
+    #declare function animated_java:karmic/animations/sword_attack2/play
+    #declare function animated_java:karmic/animations/fall/play
+    #declare function animated_java:karmic/animations/fall/stop
+    #declare function animated_java:karmic/animations/guntpstart/stop
+    #declare function animated_java:karmic/animations/guntp/stop
+    #declare function animated_java:karmic/pause_all
+    #declare function animated_java:karmic/animations/dead/play

Asset/data/asset/functions/mob/0301.karmic/death/.mcfunction

@@ -0,0 +1,17 @@
+#> asset:mob/0301.karmic/death/
+#
+# Mobの死亡時の処理
+#
+# @within function asset:mob/alias/301/death
+
+# AJ死亡モーション
+    execute as @e[type=item_display,tag=8D.AJ,sort=nearest,limit=1] run function asset:mob/0301.karmic/death/animation_reset
+    execute as @e[type=item_display,tag=8D.AJ,sort=nearest,limit=1] run function animated_java:karmic/pause_all
+    execute as @e[type=item_display,tag=8D.AJ,sort=nearest,limit=1] run function animated_java:karmic/animations/dead/play
+
+# 召喚
+    data modify storage api: Argument.ID set value 2219
+    execute at @s run function api:object/summon
+
+# Super
+    function asset:mob/super.death

Asset/data/asset/functions/mob/0301.karmic/death/animation_reset.mcfunction

@@ -0,0 +1,10 @@
+#> asset:mob/0301.karmic/death/animation_reset
+#
+#
+#
+# @within function asset:mob/0301.karmic/death/
+
+function animated_java:karmic/animations/wait/stop
+function animated_java:karmic/animations/sword_wait/stop
+function animated_java:karmic/animations/fall/stop
+function animated_java:karmic/animations/run_loop/stop

Asset/data/asset/functions/mob/0301.karmic/hurt/.mcfunction

@@ -0,0 +1,12 @@
+#> asset:mob/0301.karmic/hurt/
+#
+# Mobのダメージ時の処理
+#
+# @within function asset:mob/alias/301/hurt
+
+
+# 演出
+    playsound minecraft:entity.player.hurt hostile @a ~ ~ ~ 1 1
+
+# Super
+    function asset:mob/super.hurt

Asset/data/asset/functions/mob/0301.karmic/init/.mcfunction

@@ -0,0 +1,22 @@
+#> asset:mob/0301.karmic/init/
+#
+# Mobのinit時の処理
+#
+# @within asset:mob/alias/301/init
+
+
+# super.init呼び出し
+    function asset:mob/super.init
+
+# AJモデル召喚
+    execute rotated ~ 0 run function animated_java:karmic/summon {args:{}}
+# ノーマル限定でフードを取る
+    execute if predicate api:global_vars/difficulty/easy as @e[type=item_display,tag=8D.AJ,sort=nearest,limit=1] run function animated_java:karmic/variants/girl/apply
+# tpさせる
+    execute at @s as @e[type=item_display,tag=8D.AJ,sort=nearest,limit=1] run tp @s ~ ~ ~
+# スコア設定
+    scoreboard players set @s General.Mob.Tick -1
+
+# タグつけるやつ。スキルアクティベート内で動く
+    tag @s add 8D.Opening
+    tag @s add 8D.SkipSkillSelect

Asset/data/asset/functions/mob/0301.karmic/load.mcfunction

@@ -0,0 +1,9 @@
+#> asset:mob/0301.karmic/load
+#
+# Mobに利用するスコアボード等の初期化処理
+#
+# @within tag/function asset:mob/load
+
+#> 定義類はここに
+# @within function asset:mob/0301.karmic/**
+    scoreboard objectives add 8D.Skill dummy

Asset/data/asset/functions/mob/0301.karmic/register.mcfunction

@@ -0,0 +1,66 @@
+#> asset:mob/0301.karmic/register
+#
+# Mobのデータを指定
+#
+# @within function asset:mob/alias/301/register
+
+# 継承 (int) (オプション)
+    data modify storage asset:mob Extends append value 2000
+    function asset:mob/extends
+# 継承されることを前提とした、抽象的なモブであるかどうか(boolean)
+    data modify storage asset:mob IsAbstract set value false
+# ID (int)
+    data modify storage asset:mob ID set value 301
+# Type (string) Wikiを参照
+    data modify storage asset:mob Type set value "Enemy.Boss"
+# 干渉可能か否か (boolean)
+    data modify storage asset:mob Interferable set value true
+# 名前 (TextComponentString) (オプション)
+    data modify storage asset:mob Name set value '{"text":"業深き想い"}'
+# Mobの説明文 (TextComponentString[]) (オプション)
+    # data modify storage asset:mob Lore set value
+# 武器
+    # メインハンド (Compound(Item)) (オプション)
+        # data modify storage asset:mob Weapon.Mainhand set value
+    # オフハンド (Compound(Item)) (オプション)
+        # data modify storage asset:mob Weapon.Offhand set value
+# 武器ドロップ率 ([float, float]) (オプション)
+    # data modify storage asset:mob WeaponDropChances set value
+# 防具
+    # 頭 (Compound(Item)) (オプション)
+        # data modify storage asset:mob Armor.Head set value
+    # 胴 (Compound(Item)) (オプション)
+        # data modify storage asset:mob Armor.Chest set value
+    # 脚 (Compound(Item)) (オプション)
+        # data modify storage asset:mob Armor.Legs set value
+    # 足 (Compound(Item)) (オプション)
+        # data modify storage asset:mob Armor.Feet set value
+# 防具ドロップ率 ([float, float]) (オプション)
+    # data modify storage asset:mob ArmorDropChances set value
+# 体力 (double) (オプション)
+    data modify storage asset:mob Health set value 55000
+# 攻撃力 (double) (オプション)
+    # data modify storage asset:mob AttackDamage set value
+# 防御力 (double) (オプション) // 被ダメージがある程度大きい場合1ptにつき0.8%カット、小さい場合1ptにつき約4%カット 20pt以上は頭打ち
+    # data modify storage asset:mob Defense set value
+# 特殊防御力 (double) (オプション) // 4pointにつきダメージを大きく減らす
+    # data modify storage asset:mob SpecialDefense set value
+# 移動速度 (double) (オプション)
+    # data modify storage asset:mob Speed set value
+# 索敵範囲 (double) (オプション)
+    # data modify storage asset:mob FollowRange set value
+# ノックバック耐性 (double) (オプション)
+    # data modify storage asset:mob KnockBackResist set value
+# 属性倍率 // 1.0fで100% 最低でも25%は軽減されずに入る
+    # 物理倍率 (float) (オプション)
+        data modify storage asset:mob Resist.Physical set value 1.2
+    # 魔法倍率 (float) (オプション)
+        data modify storage asset:mob Resist.Magic set value 0.85
+    # 火倍率 (float) (オプション)
+        data modify storage asset:mob Resist.Fire set value 0.85
+    # 水倍率 (float) (オプション)
+        data modify storage asset:mob Resist.Water set value 1
+    # 雷倍率 (float) (オプション)
+        data modify storage asset:mob Resist.Thunder set value 1
+# フィールド
+    # data modify storage asset:mob Field.myValue set value

Asset/data/asset/functions/mob/0301.karmic/remove/.mcfunction

@@ -0,0 +1,15 @@
+#> asset:mob/0301.karmic/remove/
+#
+# 天使が居なくなる際に実行される処理
+#
+# @within asset:mob/alias/301/remove
+
+#> private
+# @private
+#declare function animated_java:karmic/remove/this
+
+# 消滅
+    execute as @e[type=item_display,distance=..0.1,sort=nearest,limit=1] run function animated_java:karmic/remove/this
+
+# Super!
+    function asset:mob/super.remove

Asset/data/asset/functions/mob/0301.karmic/summon/.mcfunction

@@ -0,0 +1,8 @@
+#> asset:mob/0301.karmic/summon/
+#
+# Object召喚処理の呼び出し時に実行されるfunction
+#
+# @within asset:mob/alias/301/summon
+
+# 元となるEntityを召喚する
+    summon wither_skeleton ~ ~ ~ {Tags:["MobInit","ProcessCommonTag","AlwaysInvisible"],PersistenceRequired:1b,Silent:1b,NoAI:1b}

Asset/data/asset/functions/mob/0301.karmic/summon/debug.mcfunction

@@ -0,0 +1,10 @@
+#> asset:mob/0301.karmic/summon/debug
+#
+# 動作チェック用の召喚処理 使い終わったら消してもいいかも
+#
+# @user
+# @private
+
+# 召喚
+    data modify storage api: Argument.ID set value 301
+    function api:mob/summon

Asset/data/asset/functions/mob/0301.karmic/tick/.mcfunction

@@ -0,0 +1,24 @@
+#> asset:mob/0301.karmic/tick/
+#
+# Mobのtick時の処理
+#
+# @within asset:mob/alias/301/tick
+
+# スコアを増やす
+    scoreboard players add @s General.Mob.Tick 1
+
+# 最寄りのAJにタグ付け
+    tag @e[type=item_display,tag=8D.AJ,distance=..0.01,sort=nearest,limit=1] add 8D.AJLink
+
+# その後発動するスキル
+# プレイヤーが周囲にいたらスキル選択
+    execute if score @s General.Mob.Tick matches 0 if entity @s[tag=!8D.SkipSkillSelect,tag=!8D.Opening] if entity @p[gamemode=!spectator,distance=..100] run function asset:mob/0301.karmic/tick/skill_select
+
+# スペクテイターでないプレイヤーが周囲にいないのに時間が着てしまった場合。スコアを戻す。ただし、スキップタグがある時は無視
+    execute if score @s General.Mob.Tick matches 0 if entity @s[tag=!8D.SkipSkillSelect,tag=!8D.Opening] unless entity @p[gamemode=!spectator,distance=..100] run scoreboard players set @s General.Mob.Tick -60
+
+# 選択したスキル発動
+    execute if score @s General.Mob.Tick matches 0.. run function asset:mob/0301.karmic/tick/skill_active
+
+# タグ消す
+    execute at @s run tag @e[type=item_display,tag=8D.AJ,distance=..0.01,sort=nearest,limit=1] remove 8D.AJLink

Asset/data/asset/functions/mob/0301.karmic/tick/00.opening/main.mcfunction

@@ -0,0 +1,15 @@
+#> asset:mob/0301.karmic/tick/00.opening/main
+#
+#
+#
+# @within function asset:mob/0301.karmic/tick/skill_active
+
+# アニメーション変える
+    execute if score @s General.Mob.Tick matches 0 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/wait/stop
+    execute if score @s General.Mob.Tick matches 0 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/summon/play
+
+# プレイヤーを見る
+    execute if score @s General.Mob.Tick matches 0 facing entity @p[gamemode=!spectator] feet run function asset:mob/0301.karmic/tick/common/tp
+
+# リセット
+    execute if score @s General.Mob.Tick matches 60 run function asset:mob/0301.karmic/tick/skill_reset

Asset/data/asset/functions/mob/0301.karmic/tick/01_0.dash/dash_skill_select.mcfunction

@@ -0,0 +1,29 @@
+#> asset:mob/0301.karmic/tick/01_0.dash/dash_skill_select
+#
+#
+#
+# @within function asset:mob/0301.karmic/tick/01_0.dash/main
+
+# ここに関してはランダムで決めちゃう
+    execute store result score $Random Temporary run random value 0..1
+
+# デバッグ
+    #scoreboard players set $Random Temporary 1
+# スキル選択
+    execute if score $Random Temporary matches 0 run tag @s add 8D.SkillDash1
+    execute if score $Random Temporary matches 1 run tag @s add 8D.SkillDash2
+
+# 未使用
+    execute if score $Random Temporary matches 2 run tag @s add 8D.SkillDash3
+
+# リセット
+    scoreboard players reset $Random Temporary
+
+# 前のタグ消す
+    tag @s remove 8D.SkillDash
+
+# スキップタグ付与
+    tag @s add 8D.SkipSkillSelect
+
+# スコア設定
+    scoreboard players set @s General.Mob.Tick -1

Asset/data/asset/functions/mob/0301.karmic/tick/01_0.dash/main.mcfunction

@@ -0,0 +1,26 @@
+#> asset:mob/0301.karmic/tick/01_0.dash/main
+#
+#
+#
+# @within function asset:mob/0301.karmic/tick/skill_active
+
+# モーション停止
+    execute if score @s General.Mob.Tick matches 0 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function asset:mob/0301.karmic/tick/common/reset_animation
+    execute if score @s General.Mob.Tick matches 0 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/run_start/play
+
+# プレイヤーを見る
+    execute if score @s General.Mob.Tick matches 0 facing entity @p[gamemode=!spectator] feet run function asset:mob/0301.karmic/tick/common/tp
+
+# 突っ込む
+    execute if score @s General.Mob.Tick matches 23..33 rotated ~ 0 positioned ^ ^ ^1 run function asset:mob/0301.karmic/tick/common/tp
+
+# モーション開始
+    execute if score @s General.Mob.Tick matches 33 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/run_start/stop
+    execute if score @s General.Mob.Tick matches 33 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/run_loop/play
+
+# 突っ込む
+    execute if score @s General.Mob.Tick matches 33..80 facing entity @p[gamemode=!spectator,distance=..100] eyes positioned ^ ^ ^-100 rotated as @s positioned ^ ^ ^-300 facing entity @s eyes positioned as @s rotated ~ 0 positioned ^ ^ ^0.6 run function asset:mob/0301.karmic/tick/common/tp
+# 近づいたらスコア設定
+    execute if score @s General.Mob.Tick matches 28..80 if entity @p[gamemode=!spectator,distance=..3] run scoreboard players set @s General.Mob.Tick 80
+# タグ
+    execute if score @s General.Mob.Tick matches 80 run function asset:mob/0301.karmic/tick/01_0.dash/dash_skill_select

Asset/data/asset/functions/mob/0301.karmic/tick/01_1.dash_slash1/main.mcfunction

@@ -0,0 +1,25 @@
+#> asset:mob/0301.karmic/tick/01_1.dash_slash1/main
+#
+#
+#
+# @within function asset:mob/0301.karmic/tick/skill_active
+
+# モーション変更
+    execute if score @s General.Mob.Tick matches 0 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/run_loop/stop
+    execute if score @s General.Mob.Tick matches 0 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/run_end_slash/play
+
+# プレイヤーを見る
+    execute if score @s General.Mob.Tick matches 0 facing entity @p[gamemode=!spectator] feet run function asset:mob/0301.karmic/tick/common/tp
+
+    execute if score @s General.Mob.Tick matches 0..7 at @s rotated ~ 0 positioned ^ ^ ^0.2 run function asset:mob/0301.karmic/tick/common/tp
+    execute if score @s General.Mob.Tick matches 8 rotated ~ 0 positioned ^ ^ ^3 run function asset:mob/0301.karmic/tick/common/tp
+# スラッシュ
+    execute if score @s General.Mob.Tick matches 8 positioned ^ ^ ^2 run function asset:mob/0301.karmic/tick/common/slash
+    execute if score @s General.Mob.Tick matches 8 positioned ^ ^ ^2 run function asset:mob/0301.karmic/tick/common/thunder
+    execute if score @s General.Mob.Tick matches 9 positioned ^ ^ ^2 run function asset:mob/0301.karmic/tick/common/thunder
+    execute if score @s General.Mob.Tick matches 10 positioned ^ ^ ^2 run function asset:mob/0301.karmic/tick/common/thunder
+
+# 慣性
+    execute if score @s General.Mob.Tick matches 9..16 rotated ~ 0 positioned ^ ^ ^0.2 run function asset:mob/0301.karmic/tick/common/tp
+# リセット
+    execute if score @s General.Mob.Tick matches 34 run function asset:mob/0301.karmic/tick/skill_reset

Asset/data/asset/functions/mob/0301.karmic/tick/01_2.dash_shot/main.mcfunction

@@ -0,0 +1,27 @@
+#> asset:mob/0301.karmic/tick/01_2.dash_shot/main
+#
+#
+#
+# @within function asset:mob/0301.karmic/tick/skill_active
+
+# モーション変更
+    execute if score @s General.Mob.Tick matches 0 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/run_loop/stop
+    execute if score @s General.Mob.Tick matches 0 as @e[type=item_display,tag=8D.AJ,tag=8D.AJLink,sort=nearest,limit=1] run function animated_java:karmic/animations/run_end_sliding/play
+
+# プレイヤーを見る
+    execute if score @s General.Mob.Tick matches 0 facing entity @p[gamemode=!spectator] feet run function asset:mob/0301.karmic/tick/common/tp
+
+# 突っ込む
+    execute if predicate api:global_vars/difficulty/min/hard if score @s General.Mob.Tick matches 0..15 facing entity @p[gamemode=!spectator,distance=..100] eyes positioned ^ ^ ^-100 rotated as @s positioned ^ ^ ^-300 facing entity @s eyes positioned as @s rotated ~ 0 run function asset:mob/0301.karmic/tick/common/tp
+    execute if score @s General.Mob.Tick matches 0..28 at @s rotated ~ 0 positioned ^ ^ ^0.2 run function asset:mob/0301.karmic/tick/common/tp
+# 撃つ
+    execute if score @s General.Mob.Tick matches 9 rotated ~ -6 positioned ~ ~0.7 ~ positioned ^ ^ ^0.3 run function asset:mob/0301.karmic/tick/common/shot/main
+    execute if score @s General.Mob.Tick matches 12 rotated ~ -6 positioned ~ ~0.7 ~ positioned ^ ^ ^0.3 run function asset:mob/0301.karmic/tick/common/shot/main
+    execute if score @s General.Mob.Tick matches 15 rotated ~ -6 positioned ~ ~0.7 ~ positioned ^ ^ ^0.3 run function asset:mob/0301.karmic/tick/common/shot/main
+
+# 慣性
+    execute if score @s General.Mob.Tick matches 28..36 rotated ~ -20 positioned ^ ^ ^0.4 run function asset:mob/0301.karmic/tick/common/tp
+    execute if score @s General.Mob.Tick matches 38..46 rotated ~ 10 positioned ^ ^ ^0.4 run function asset:mob/0301.karmic/tick/common/tp
+
+# リセット
+    execute if score @s General.Mob.Tick matches 46 run function asset:mob/0301.karmic/tick/skill_reset

Asset/data/asset/functions/mob/0301.karmic/tick/01_3.dash_slash2/main.mcfunction

@@ -0,0 +1,7 @@
+#> asset:mob/0301.karmic/tick/01_3.dash_slash2/main
+#
+# いつか作りたい
+#
+# @within function asset:mob/0301.karmic/tick/skill_active
+
+# 未使用領域